☰

自动创建 7z 文件脚本，但需要从输出文件名中删除旧文件扩展名

tag-icon • tag-icon 7-zip
自动创建 7z 文件脚本，但需要从输出文件名中删除旧文件扩展名

在由@Enteleform 编写的脚本中可以找到此处。（如下）

@Echo OFF
SetLocal EnableDelayedExpansion



Rem //  7-Zip Executable Path
Set sevenZip="C:\Program Files\7-Zip\7z.exe"



Rem // START: NewLine Variable Hack
Set newLine=^


Rem // END: NewLine Variable Hack !! DO NOT DELETE 2 EMPTY LINES ABOVE !!



Rem //  Set ErrorLog Variables
Set errorCount=0
Set separator=--------------------------------------------------------
Set errorLog=!newLine!!newLine!!separator!!newLine!!newLine!
Set errorPrefix=ERROR @:
Set successMessage=All Files Were Successfully Archived



Rem //  Loop Through Each Argument
SetLocal DisableDelayedExpansion
for %%x in (%*) do (

    Rem //  Use Current Argument To set File, Folder, & Archive Paths
    SetLocal DisableDelayedExpansion
    Set filePath="%%~x"
    Set directoryFiles="%%~x\*"
    Set archivePath="%%~x.zip"
    SetLocal EnableDelayedExpansion

    Rem //  Source Is A Folder
    if exist !directoryFiles! (
            Set sourcePath=!directoryFiles!
    )

    Rem //  Source Is A File
    if not exist !directoryFiles! (
            Set sourcePath=!filePath!
    )

    Rem //  Print Separator To Divide 7-Zip Output
    echo !newLine!!newLine!!separator!!newLine!!newLine!

    Rem //  Add Files To Zip Archive
    !sevenZip! A -TZIP !archivePath! !sourcePath!

    Rem //  Log Errors
    if ErrorLevel 1 (
        Set /A errorCount=errorCount+1
        Set errorLog=!errorLog!!newLine!!errorPrefix!!sourcePath!
    )
)



Rem //  Print ErrorLog
if !errorCount!==0 (
    Set errorLog=!errorLog!!newLine!!successMessage!
)
Echo !errorLog!!newLine!!newLine!!newLine!



Rem //  Keep Window Open To View ErrorLog
pause

它运行良好，但是脚本在创建的 7z 文件的命名中包含了原始文件扩展名。（例如“Picture1.jpg.7z”）如何从新创建的 7z 文件的名称中删除原始文件扩展名？（例如“Picture1.7z”）

答案1

如何从新创建的 7z 文件的名称中去除原始文件扩展名？

使用%~n1 参数扩展。

代替：

set archivePath="%%~x.zip"

和：

set archivePath="%%~nx.zip"

参数扩展

...

%~n1扩展%1为不带文件扩展名的文件名C:\utils\MyFile，或者如果仅存在路径（没有尾随反斜杠） - 则扩展为该路径中的最后一个文件夹。

来源 -参数

进一步阅读

相关内容