☰

在并排的浏览器窗口中同时向下滚动

tag-icon • tag-icon google-chrome firefox browser scrolling
在并排的浏览器窗口中同时向下滚动

我的屏幕上通常会同时运行两个网络浏览器实例。当我阅读新闻或外语文章时，我会在一个浏览器上打开翻译的文本，覆盖屏幕的一半，而另一个窗口中运行的原文则覆盖屏幕的另一半。

现在，我希望能够同时向下滚动在同一浏览器的两个不同实例上运行的两个页面，以便我可以比较翻译文本和原始文本。我使用 Firefox 或 Chrome。有没有办法让它同时向下滚动功能发挥作用？

答案1

这可以通过自动热键使用以下脚本来执行 magic，该脚本应存储在.ahk文件中以供执行。双击该文件以启动脚本，右键单击托盘栏中的绿色“H”图标并选择退出来停止脚本。

该脚本是为两个窗口的协调滚动而编写的。您必须先逐个选择要滚动的窗口。该脚本复制了以下用于协调滚动的键：向上滚轮、向下滚轮、向上翻页、向下翻页。

该脚本使用一些热键进行初始化。您可以编辑它以使用其他热键或删除不需要的热键。我选择的那些热键如下所述。

F1 : Starts a new group of windows
F2 : Includes the currently active window in the group
F3 : Shows the windows in the group even if minimized
F4 : Closes all windows in the group

这是脚本。它在我的测试中有效。

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#SingleInstance Force
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
Process, Priority, , High
SetWinDelay 0
g = 1                   ; Used to generate unique group names

; Reload script to reinitialize all variables, since there is no delete group
f1::
Reload
return

; Add currently active window to the group
f2::
WinGet, active_id, ID, A
GroupAdd, grpname, ahk_id %active_id%
return

; Restore all windows in the group to be visible
f3::WinRestore, ahk_group grpname
return

; Close all windows in the group
f4::GroupClose, grpname , A
Reload
return

; This intercepts scroll keys on the active window and duplicates them on the other window
#IfWinActive ahk_group grpname
WheelUp::
WheelDown::
PgUp::
PgDn::
    MouseGetPos, mX, mY                 ; remember mouse position in current window
    Send {%A_ThisHotKey%}
    GroupActivate grpname               ; activate the next window of this group
    If (A_ThisHotKey = "WheelUp" || A_ThisHotKey = "WheelDown")
        MouseMove, 200, 200, 0          ; move the mouse over the currently active window 
    Send {%A_ThisHotKey%}   
    GroupActivate grpname               ; Activate previous window
    MouseMove, mX, mY, 0                ; Restore its mouse position
return

答案2

你可以尝试这个https://github.com/takatama/sync-scroll-chrome-extension。它是一个 chrome 扩展，只需打开 chrome://extensions/，单击加载已解压的代码，打开刚刚下载的代码，尽情享受吧！！

答案3

diffsite 是一款基于 Web 的网站并排比较工具。与 takatamas sync-scroll-chrome-ext 不同，它允许比较两个不同的 URL。

答案4

您可以使用此 Chrome 扩展程序“simultaneous-scrolling”同时滚动两个选项卡！

同时滚动

相关内容