☰

根据 4 个条件计算不同值 (Excel 公式)

tag-icon • tag-icon microsoft-excel worksheet-function microsoft-excel-2010 microsoft-excel-2007
根据 4 个条件计算不同值 (Excel 公式)

我有如下的表格结构：

    [A]    [B]    [C]    [D]    [E]
[1] Dog    Big    2018   02     123
[2] Dog    Big    2018   02     123
[3] Cat    Small  2019   05     123
[4] Dog    Big    2018   02     124
[5] Cat    Small  2019   05     123

列 [E] 包含重要的重复值。任务是过滤列 [A]、[B] 和 [C]（忽略 [D]），并根据列 [E] 在每个数据集上查找不同的值。

步骤 1：通过执行 COUNTIFS 来识别并计算列 [A]、[B]、[C] 的唯一组合的出现次数

=COUNTIFS(
 A:A,A1,
 B:B,B1,
 C:C,C1,
)

这显示给我：

第 1 行 = 3

第 2 行 = 3

第 3 行 = 2

第 4 行 = 3

第 5 行 = 2

步骤 2：针对步骤 1 中确定的唯一组合，计算这些组合加上列 [E] 的唯一组合

第 1 行 = 应为 2

第 2 行 = 应为 2

第 3 行 = 应为 1

第 4 行 = 应为 2

第 5 行 = 应为 1

这些结果是因为 A、B 和 C 列中有两个唯一组合：{Dog, Big, 2018} 和 {Cat, Small, 2019}。{Dog, Big, 2018} 与 E 列中的两个唯一值相关联，而 {Cat, Small, 2019} 与 E 列中的一个唯一值相关联。

答案1

将 SUMPRODUCT 与 COUNTIFS 结合使用：

=SUMPRODUCT(($A$1:$A$5=A1)*($B$1:$B$5=B1)*($C$1:$C$5=C1)/(COUNTIFS($A$1:$A$5,A1,$B$1:$B$5,B1,$C$1:$C$5,C1,$E$1:$E$5,$E$1:$E$5)+($A$1:$A$5<>A1)+($B$1:$B$5<>B1)+($C$1:$C$5<>C1)))

COUNTIFS 将总数除以每行是否匹配，然后将它们相加。例如，第 1 行最终解析SUMPRODUCT({1,1,0,1,0}/{2,2,2,1,2})为SUMPRODUCT({.5,.5,0,1,0})或2

在此处输入图片描述

答案2

借助以下工具排序：

Excel：计算两列中的唯一实例

和

https://professor-excel.com/number-unique-records/

潜在答案（有效）：

=SUM(IF(FREQUENCY(IF($A$1:$A$5=A1,IF($B$1:$B$5=B1,IF($C$1:$C$5=C1,MATCH($E$1:$E$5,$E$1:$E$5,0)))),ROW($E$1:$E$5)-MIN(ROW($E$1:$E$5))+1),1))

相关内容