☰

在另一个工作表中查找参考表中未包含的信息

tag-icon • tag-icon microsoft-excel worksheet-function
在另一个工作表中查找参考表中未包含的信息

我有两张工作表，一张是我的参考表，上面列有产品清单。我还有其他工作表，上面有许多相同的产品，但也有一些参考表中没有的新产品。我想找到参考表中未包含但其他工作表上存在的产品清单。

例如

參考表：

RED
BLUE
GREEN
BLACK
WHITE

其他片材

RED 
CYAN
BLUE
WHITE
YELLOW
GREEN

我不需要知道另一张纸没有黑色，但需要知道它包含青色和黄色。

有没有办法做到这一点？

答案1

以下是一种方法：
在此处输入图片描述

和公式：
在此处输入图片描述

这是单元格 F3 中的公式：=IF(ISNUMBER(MATCH(E3,B$1:B$8,0)),0,1) 以及单元格 B10 中的公式：=IFERROR(VLOOKUP(A10,$D$3:$E$21,2,FALSE),"")

答案2

如果您有适用于 MS365 的 Excel，则可以将 FILTER 函数与 ISNA 和 XMATCH 结合使用，以返回参考表中任何新值/缺失值的动态列表。使用提供的示例数据，如果值在两个工作表中的 A 列中，则以下公式将在溢出数组中返回 {"CYAN";"YELLOW"}：

=FILTER('Other Sheet'!A2:A7, ISNA(XMATCH('Other Sheet'!A2:A7, 'Reference Sheet'!A2:A6)), "No new products")

如果“其他工作表”包含每个产品的多条记录，您也可以使用 UNIQUE 函数返回简化列表：

=UNIQUE(FILTER('Other Sheet'!A2:A7, ISNA(XMATCH('Other Sheet'!A2:A7, 'Reference Sheet'!A2:A6)), "No new products"))

如果您需要将参考表与多个“其他表”进行比较，则可以使用 VSTACK 函数从其他表汇编完整的产品列表。例如：

=LET(
   arr, UNIQUE(VSTACK('Other Sheet1'!A2:A7, 'Other Sheet2'!A2:A9)),
   FILTER(arr, ISNA(XMATCH(arr, 'Reference Sheet'!A2:A6)), "No new products")
)

再次请注意，这些方法仅适用于 Excel for MS365。

相关内容