☰

有没有更快捷的方法来切换 Windows 粘滞键？

tag-icon • tag-icon accessibility
有没有更快捷的方法来切换 Windows 粘滞键？

我正在寻找一种比每次按下 Shift 键 5 次更快捷的方法来切换粘滞键。

也许某个地方的某些设置允许定义不同的激活热键？

或者某种命令行选项或注册表项更改会激活粘滞键？（然后我可以使用合适的命令创建 Windows 快捷方式并为其指定热键。）

我已经考虑过使用像 NirCMD 这样的实用程序来通过重复 5 次的“sendkeypress shift”命令模拟按下 Shift 键，但由于某种原因，Windows 10 不会将其识别为粘滞键的触发器。

答案1

您可以使用免费AutoHotkey V1。

以下示例脚本使用F9打开或关闭粘滞键：

SPI_GETSTICKYKEYS:=0x003A
SPI_SETSTICKYKEYS:=0x003B
SKF_STICKYKEYSON:=0x1

VarSetCapacity(STICKYKEYS,8) ; DWORD cbSize;DWORD dwFlags;
NumPut(8,&STICKYKEYS,"UInt")
F9::
  DllCall("SystemParametersInfo","UInt",SPI_GETSTICKYKEYS,"UInt",8,"PTR",&STICKYKEYS,"UInt",0)
  dwFlags:=NumGet(&STICKYKEYS,4,"Uint")
  If (dwFlags & SKF_STICKYKEYSON)
    dwFlags-=SKF_STICKYKEYSON
  else dwFlags|=SKF_STICKYKEYSON
  ToolTip % "STICKYKEYS are " (dwFlags & SKF_STICKYKEYSON ? "ON" : "OFF")
  SetTimer,ToolTipOff,-1000
  NumPut(dwFlags,&STICKYKEYS,4,"UInt")
  DllCall("SystemParametersInfo","UInt",SPI_SETSTICKYKEYS,"UInt",8,"PTR",&STICKYKEYS,"UInt",0)
Return
ToolTipOff:
ToolTip 
Return

安装 AutoHotKey 后，将上述文本放入一个.ahk文件中并双击进行测试。您可以通过右键单击托盘栏中的绿色 H 图标并选择退出来停止脚本。要让它在登录时运行，请将其放在 的启动组中
C:\Users\USER-NAME\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup。

来源 ：粘滞键激活无法通过热键进行

有用的 AutoHotkey 文档：

相关内容