我有一个具有值的单元格A1 = 3,500,000。
我想按照以下公式计算 350 万美元的费用：
第一个一百万是 7%，第二个一百万是 5%，第三个一百万是 3%，之后是 2%。
理想情况下，我希望所有这些都发生在 1 个单元格中，因此 1 个单元格中只有 1 个公式，而不是使用一整张表格或一张工作表来执行此操作。
谢谢！
答案1
当然，可以使用单个单元格中的单个公式来解决这个问题，但如果您想让公式易于理解和更改，表格会更简洁。
--
单细胞解决方案
对于单元格解决方案，如果值在 A1 中，则此公式将计算您的分级费用：
= A1 * 0.07 + MAX(A1-1000000,0) * -0.02 + MAX(A1-2000000,0) * -0.02 + MAX(A1-3000000,0) * -0.01
将总值乘以 0.07，然后为每个等级减去新等级和前一等级之间的费用差额（有很多方法可以做到这一点 - 我只提供了一个例子）。
--
简单表格解决方案
对于简单的表格解决方案，您可以执行以下操作：
计算各层级价值的公式：
E2：=MIN（C2，$A$1）
E3：=MIN（C3，$A$1）-SUM（$E$2:E2）
E4：=MIN（C4，$A$1）-SUM（$E$2:E3）
E5： =MAX($A$1-C4,0)
总费用计算公式：
D6：=SUMPRODUCT(D2:D5,E2:E5)
此设置是动态的；您可以更改阈值或费用，而公式仍然有效。
如果您将来可能需要更多层级，建议使用 XML 表。如果您只使用 4 个层级，但这些层的门槛和费用可能会发生变化，则上面的简单表格就足够了
答案2
人们可以使用结构合理的查找表来解决此问题（以及非常相似的税收计算问题）。
您的佣金表
- 第 1 列 = 销售基准金额
- 第 2 列 = 各层级的百分比
- 第 3 列 = 该等级之前赚取的佣金金额
在下表中：
G1: 0
G2: =(E3-E2)*F2+G2
并根据需要填写
然后使用数据A1
=(A1-VLOOKUP(A1,commissionTbl,1))*VLOOKUP(A1,commissionTbl,2)+VLOOKUP(A1,commissionTbl,3)
请注意，如果您的佣金结构发生变化，编辑表格很简单 - 比编辑公式简单得多。
答案3
我想展示三种可能性。
- 分别计算第 1 层的值，然后计算第 2 层、第 3 层和第 4 层的值，最后得出总计。
为此，请检查单元格中的公式：
E2： =IF(D2<=1000000, D2*0.07, 1000000*0.07)
F2： =IF(D2>1000000, IF(D2<=2000000, (D21-1000000)*0.05, 1000000*0.05), 0)
G2级：
=IF(D2>2000000, IF(D2<=3000000, (D2-2000000)*0.03, 1000000*0.03), 0)
结论2： =IF(D2>3000000, (D2-3000000)*0.02, 0)
最后一个是I2： =SUM(E2:H2)
2. 另一种是 中的单一公式解决方案I5。
单元格 I5：
=IF(D2<=1000000, D2*0.07, IF(D2<=2000000, 1000000*0.07 + (D2-1000000)*0.05, IF(D2<=3000000, 1000000*0.07 + 1000000*0.05 + (D2-2000000)*0.03, 1000000*0.07 + 1000000*0.05 + 1000000*0.03 + (D2-3000000)*0.02)))
3. 最后一个公式适用I7于使用 LET 函数的 Excel 高版本。
单元格 I7：
=LET( amount, D2,
tier1, MIN(amount, 1000000),
tier2, MAX(0, MIN(amount, 2000000) - 1000000),
tier3, MAX(0, MIN(amount, 3000000) - 2000000),
tier4, MAX(0, amount - 3000000),
tier1*0.07 + tier2*0.05 + tier3*0.03 + tier4*0.02)
注意： 根据需要调整单元格引用。