验证文件中预告片中的记录计数

Question 1

您的代码似乎假设数据用作|字段分隔符，但显然没有。看来您想断言确实存在一头记录 ( HDR...) 和一尾记录 ( TRL) 并且尾记录提到了正确的数字，即中间数据记录 ( ) 的数量DTL...。

我假设该文件可能包含空行，并且应该忽略这些空行。

该awk程序：

$1 ~ /^HDR/ { h++ }
$1 ~ /^DTL/ { d++ }
$1 == "TRL" { t++; ok = (d == $2) }
END { exit !(h == 1 && t == 1 && ok) }

对于每条HDR...记录，h都会递增。对于每条DTL...记录，d都会递增。当TRL找到一条记录时，我们会递增t并计算一个布尔值，ok该值告诉我们数据行数是否正确。

如果我们END恰好遇到了一个标头和尾部记录，并且该布尔ok值为真的。

如果任何记录出现乱序，以下代码还会以非零退出状态退出（同时允许零数据记录）：

BEGIN { ok = 1 }
$1 ~ /^HDR/ { h++; ok = (h == 1 && d ==  0 && t == 0) }
$1 ~ /^DTL/ { d++; ok = (h == 1            && t == 0) }
$1 == "TRL" { t++; ok = (h == 1 && d == $2 && t == 1) }
!ok { exit }
END { exit !(h == 1 && t == 1 && ok) }

这可以保持布尔变量中数据的整体有效性ok，并在该变量翻转到时以非零退出状态退出错误的（或者如果仍然存在，则退出状态为零真的整个代码的运行过程）。我们仍然需要确保在到达块时恰好看到一个头记录和尾记录END，否则它将验证空文件是否正确。

要运行上述任一awk程序，请将其放入文件中（此处validate.awk）并使用

if awk -f validate.awk sample.txt; then
    echo 'file ok'
else
    echo 'file not validated'
fi

或者，在命令行上将整个程序作为单引号字符串给出：

if awk '$1 ~ /^HDR/ { h++ } $1 ~ /^DTL/ { d++ } $1 == "TRL" { t++; ok = (d == $2) } END { exit !(h == 1 && t == 1 && ok) }' sample.txt
then
    echo 'file ok'
else
    echo 'file not validated'
fi

寻址一条评论说该TRL记录可能看起来像TRL0009 93084.00where 0009is the count of all types of record。

在这种情况下，第一个awk程序可能看起来像

$1 ~ /^HDR/ { h++ }
$1 ~ /^DTL/ { d++ }
$1 ~ /^TRL/ { t++; ok = ( d == substr($0,4,4) - 2 ) }
END { exit !(h == 1 && t == 1 && ok) }

这里，substr($0,4,4)用于挑选$0（原始输入行）中从位置四开始、长度为四的字符串。我们从该数字中减去 2 以计算头记录和尾记录。

Answer