☰

如何编写 zsh 完成的自动化测试？

tag-icon • tag-icon zsh autocomplete testing
如何编写 zsh 完成的自动化测试？

我有一个项目，其中自动生成 zsh 补全函数。在我的工作过程中，我发现了一些极端情况和错误，我只是将其写下来，并确保在进行更改时重新测试。显然，我想编写一个合适的测试套件，但我不知道如何编写。

对于 bash 完成，测试非常简单——设置COMP_*变量，运行函数，然后检查COMP_REPLY.我想为 zsh 做类似的事情。

我已尽我所能阅读 compsys 文档，但没有看到解决方案。

我想手动设置上下文，运行我的完成，然后查看一系列描述或其他内容。

有没有人找到测试完成情况的方法？

答案1

在 Zsh 中测试完成情况要复杂一些。这是因为 Zsh 的完成命令只能从完成小部件内部运行，而该小部件又只能在 Zsh 行编辑器处于活动状态时调用。为了能够在脚本内完成补全，我们需要使用所谓的伪终端，其中我们可以有一个活动命令行来激活完成小部件：

# Set up your completions as you would normally.
compdef _my-command my-command
_my-command () {
        _arguments '--help[display help text]'  # Just an example.
}

# Define our test function.
comptest () {
        # Add markup to make the output easier to parse.
        zstyle ':completion:*:default' list-colors \
                'no=<COMPLETION>' 'lc=' 'rc=' 'ec=</COMPLETION>'
        zstyle ':completion:*' group-name ''
        zstyle ':completion:*:messages' format \
                '<MESSAGE>%d</MESSAGE>'
        zstyle ':completion:*:descriptions' format \
                '<HEADER>%d</HEADER>'

        # Bind a custom widget to TAB.
        bindkey '^I' complete-word
        zle -C {,,}complete-word
        complete-word () {
                # Make the completion system believe we're on a 
                # normal command line, not in vared.
                unset 'compstate[vared]'

                # Add a delimiter before and after the completions.
                # Use of ^B and ^C as delimiters here is arbitrary.
                # Just use something that won't normally be printed.
                compadd -x $'\C-B'
                _main_complete "$@"
                compadd -J -last- -x $'\C-C'

                exit
        }

        vared -c tmp
}

zmodload zsh/zpty  # Load the pseudo terminal module.
zpty {,}comptest   # Create a new pty and run our function in it.

# Simulate a command being typed, ending with TAB to get completions.
zpty -w comptest $'my-command --h\t'

# Read up to the first delimiter. Discard all of this.
zpty -r comptest REPLY $'*\C-B'

zpty -r comptest REPLY $'*\C-C'  # Read up to the second delimiter.

# Print out the results.
print -r -- "${REPLY%$'\C-C'}"   # Trim off the ^C, just in case.

zpty -d comptest  # Delete the pty.

运行上面的例子将打印出：


<HEADER>option</HEADER>
<COMPLETION>--help    display help text</COMPLETION>

如果您不想测试整个完成输出，而只想测试将在命令行上插入的字符串，请参阅https://stackoverflow.com/questions/65386043/unit-testing-zsh-completion-script/69164362#69164362

相关内容