☰

将一行拆分为多行，同时保留第一列

tag-icon • tag-icon awk text-formatting
将一行拆分为多行，同时保留第一列

有没有办法重新格式化文本文件

'n      n / [ ] / m / N        
'ns      @ s / @ z / @ / j @ z / j @ s        
'r      r        
's      s / z / [ ]    
...

到

'n      n 
'n      [ ] 
'n      m
'n      N        
'ns      @ s 
'ns      @ z 
'ns      @ 
'ns      j @ z 
'ns      j @ s        
'r      r        
's      s 
's      z 
's      [ ]    
...

也就是说，如果我们/在一行中遇到 s，则该行将根据/s 的位置进行分割，同时保留第一列（第一列之后始终有 6 个空格）。

我尝试过tr / '\n' < filename1 > filename2这样可以将线条分开

'n      n 
 [ ] 
 m 
 N        
 'ns      @ s 
 @ z 
 @ 
 j @ z 
 j @ s        
 'r      r        
 's      s 
 z 
 [ ]  
...

但我无法将第一列保留在连续行中。

答案1

每个 Unix 机器上的任何 shell 中的 awk：

如果这是第一个字段和该行其余部分之间的制表符：

$ awk 'BEGIN{FS=OFS="\t"} {n=split($2,f," */ *"); for (i=1; i<=n; i++) print $1, f[i]}' file
'n      n
'n      [ ]
'n      m
'n      N
'ns     @ s
'ns     @ z
'ns     @
'ns     j @ z
'ns     j @ s
'r      r
's      s
's      z
's      [ ]

或者如果它是一系列空白字符：

$ awk 'match($0,/[^ ]+ +/){key=substr($0,1,RLENGTH); n=split(substr($0,1+RLENGTH),f," */ *"); for (i=1; i<=n; i++) print key, f[i]}' file
'n       n
'n       [ ]
'n       m
'n       N
'ns      @ s
'ns      @ z
'ns      @
'ns      j @ z
'ns      j @ s
'r       r
's       s
's       z
's       [ ]

或者如果它是前面的固定 8 个字符宽度字段，那么您可以执行以下任一操作：

$ awk '{key=substr($0,1,8); n=split(substr($0,9),f," */ *"); for (i=1; i<=n; i++) print key, f[i]}' file
'n       n
'n       [ ]
'n       m
'n       N
'ns      @ s
'ns      @ z
'ns      @
'ns      j @ z
'ns      j @ s
'r       r
's       s
's       z
's       [ ]

或者：

$ awk '{n=split(substr($0,9),f," */ *"); for (i=1; i<=n; i++) printf "%-8s%s\n", $1, f[i]}' file
'n      n
'n      [ ]
'n      m
'n      N
'ns     @ s
'ns     @ z
'ns     @
'ns     j @ z
'ns     j @ s
'r      r
's      s
's      z
's      [ ]

答案2

sed  "s/ /\//" filename| awk -F "/" '{for(i=2;i<=NF;i++)print $1,$i}'

输出

'n      n 
'n  [ ] 
'n  m 
'n  N        
'ns      @ s 
'ns  @ z 
'ns  @ 
'ns  j @ z 
'ns  j @ s        
'r      r        
's      s 
's  z 
's  [ ]

相关内容