根据部分拆分 pdf 文档

Question 1

我喜欢用于pdftk此类工作。

如果我使用 Latex 创建一个基本文档，它可能如下所示：

\documentclass{report}
\usepackage{blindtext} % For lorem ipsum text
\usepackage{hyperref} % Turns chapters/sections into bookmarks

\begin{document}

\chapter{First Chapter}
\Blindtext[10]

\section{Subsection of chapter 1}
\Blindtext[3]

\chapter{Second Chapter}
\Blindtext[20]

\chapter{Third Chapter}
\Blindtext

\pdfbookmark{Example bookmark}{A}
\Blindtext

\end{document}

当我运行它时pdflatex，它会生成一个 13 页的 PDF，其中每个章节都有自动书签、第 1.1 节的深度书签、稍后的手动书签以及许多 lorem ipsum 段落。

现在我们有了一个 pdf 文件，我们可以用它pdftk来获得一些关于它的见解。数据很多，所以我将其缩减为有趣的部分。

$ pdftk sample.pdf dump_data
InfoBegin
...
NumberOfPages: 13
BookmarkBegin
BookmarkTitle: First Chapter
BookmarkLevel: 1
BookmarkPageNumber: 1
BookmarkBegin
BookmarkTitle: Subsection of chapter 1
BookmarkLevel: 2
BookmarkPageNumber: 3
BookmarkBegin
BookmarkTitle: Second Chapter
BookmarkLevel: 1
BookmarkPageNumber: 5
BookmarkBegin
BookmarkTitle: Third Chapter
BookmarkLevel: 1
BookmarkPageNumber: 11
BookmarkBegin
BookmarkTitle: Example bookmark
BookmarkLevel: 1
BookmarkPageNumber: 12
PageMediaBegin
...

当我们点击BookmarkBegin标签时，我们就知道我们有一个书签。当我们看到时，BookmarkTitle: X我们知道我们已经到达了部分X。BookmarkPageNumber:每个书签都有一个关联的书签。您可以将其用于您的拆分。您还可以使用BookmarkLevel来过滤您想要拆分的级别（章节、部分、小节）。

假设您想在第 1 章和第 2 章之间进行拆分。从数据中我们可以看到，我们需要在第 4 页之前添加拆分：

BookmarkTitle: Second Chapter
BookmarkPageNumber: 5

现在我们有了页码，我们可以用来pdftk进行分割。这实际上涉及到cat在特定页面上使用：

pdftk sample.pdf cat 1-4 output sample-1.pdf
pdftk sample.pdf cat 5-end output sample-2.pdf

让我们采用更通用的方法，并将其编写为名为 .pdf 的 pdf 脚本sample.pdf。让我们在每个高级书签处拆分 PDF（过滤掉该部分）。

首先，让我们将书签标签转换为更易于解析的格式，我们可以在其中写入一些内容awk（我将其另存为parser.awk）

#!/bin/awk -f
BEGIN {
    FS=": "
    OFS=";"
}
/^BookmarkBegin/ {
  if (this_level > 1) { # Only handle high-level sections
    next
  }
  if (this_page == "" || this_title == ""){
    next
  }
  if (last_page != "" && last_title != "") {
    print last_title, last_page, this_page-1
  }
  last_title=this_title
  last_page=this_page
  this_title=this_page=this_level=""
}
/^BookmarkTitle:/ {
    this_title=$2
}
/^BookmarkPageNumber:/ {
    this_page=$2
}
/^BookmarkLevel:/ {
    this_level=$2
}
END {
  print last_title, last_page, this_page-1
  print this_title, this_page, "end"
}

在这里，我假设标题不包含 a ;，因此我使用它作为输出分隔符。该脚本输出：

每个部分的名称
该部分的首页
本节的最后一页。

$ pdftk sample.pdf dump_data | awk -f parser.awk
First Chapter;1;4
Second Chapter;5;10
Third Chapter;11;11
Example bookmark;12;end

现在让我们迭代每一行并pdftk在 bash 中调用它：

#!/bin/bash                                                                     
                                                                                
sequence=1                                                                      
                                                                                
pdftk sample.pdf dump_data | awk -f parser.awk | \                              
while IFS=";" \                                                                 
read -r title start end                                                         
do                                                                              
  pdftk sample.pdf cat "$start"-"$end" output sample-$sequence-"$title".pdf      
  sequence=$((sequence+1))                                                      
done

这给你留下了以下内容：

$ ls *.pdf
'sample-1-First Chapter.pdf'
'sample-2-Second Chapter.pdf'
'sample-3-Third Chapter.pdf'
'sample-4-Example bookmark.pdf'
sample.pdf

这样做的一个限制是，当同一页面上有多个书签或书签很少时，它会有点混乱。

Answer