☰

如果一个文件中的列部分匹配另一个文件中的列，则匹配，然后打印两个文件中的列

tag-icon • tag-icon shell awk grep
如果一个文件中的列部分匹配另一个文件中的列，则匹配，然后打印两个文件中的列

我有 2 个文件，其中字段以逗号分隔 -

aks@dev1:~$ cat dir.txt

/home/aks/cleanup,512

/home/aks/git,208

/home/aks/github,424


/home/aks/predirsize,216

/home/aks/sample,288004

aks@dev1:~$ cat config.txt

/home/aks/cleanup,1,7,2

/home/aks/sample/aks,1,2,1

/home/vbht/test_bkup,1,7,None

我需要在 config.txt 的第一个字段中查找 dir.txt 的第一个字段，如果它完全或部分匹配，则打印 config.txt 的第一个字段、dir.txt 的第二个字段、dir.txt 的第二个、第三个和第四个字段配置.txt。

期望输出 -

/home/aks/cleanup,512,1,7,2

/home/aks/sample/aks,288004,1,2,1

答案1

这是一个awk方法：

$ awk -F, -v OFS=, '{ if(/^$/){next} if(NR==FNR){f1[$1]=$2;} else{for(path in f1){ if($1 ~ path ){print $1,f1[path],$2,$3,$4}}}}' dir.txt config.txt 
/home/aks/cleanup,512,1,7,2
/home/aks/sample/aks,288004,1,2,1

这是同样的事情分成多行并进行了解释。您仍然可以将其直接复制/粘贴到终端中：

awk -F, -v OFS=, '
 { 
    ## Skip empty lines
    if(/^$/){ next } 

    ## If this is the first file, store the first field 
    ## as a key and the second field as its value in the 
    ##associative array f1 
    if(NR==FNR){ f1[$1]=$2 } 

    ## If this is the second file
    else{
        ## for each of the keys in f1, the paths
        for(path in f1){ 
            ## If the 1st field of this line matches a path
            if($1 ~ path){
                ## print all the things
                print $1,f1[path],$2,$3,$4
            }
        }
    }
 }' dir.txt config.txt

相关内容