最小/最大/平均交易持续时间的计算缺少输出中最短交易的 ID

Question

您想要实现的目标可以完全在awk脚本中实现，这比使用 shell 循环进行文本处理要高效得多。我会推荐以下程序（我们称之为analyze_timing.awk）：

#!/usr/bin/awk -f

function timediff(start,end,    stfld,endfld,diff) {
    split(start,stfld, /:/)
    split(end,  endfld,/:/)

    if (endfld[1]<stfld[1]) {
        diff=(3600*(endfld[1]+24) + 60*endfld[2] + endfld[3])
    }
    else {
        diff=(3600*endfld[1] + 60*endfld[2] + endfld[3])
    }

    diff -= (3600*stfld[1] + 60*stfld[2] + stfld[3])
    return diff
}


$5 ~ /^:\.+starting_transaction/ {laststart=$2;next}

$5 ~ /^:\.+ending_transaction/ {
    n_transact++
    duration=timediff(laststart, $2)
    avg+=duration
    
    if (n_transact==1) {
        shortest=duration
        longest=duration
        min_id=substr($4,2)
    }
    else {
        if (duration<shortest) {
            shortest=duration
            min_id=substr($4,2)
        } else if (duration>longest) {
            longest=duration
        }
    }
}

END {
    printf("avg: %f | max: %f | min: %f | minID: %d\n", avg/n_transact, longest, shortest, min_id)
}

这将首先定义一个函数timediff()来计算两个时间戳之间经过的时间，如示例所示。为简单起见，假设一笔交易需要不到 24 小时。

然后，它将检查一行的第 5 个字段是否以starting_transactiona:和任意数量的开头，.并将时间记录在变量中laststart。如果第五个字段同样以开头ending_transaction，它将计算差异laststart并填充用于计算最小/最大/平均值的变量。如果是迄今为止最短的交易，则 ID 将记录在中min_id。

最后，程序根据需要打印摘要。

你会称其为

awk -f analyze_timing.awk log-file.txt

Answer 1