☰

如何将 zsh 自动完成功能与包装函数参数和现有命令结合起来

tag-icon • tag-icon zsh autocomplete
如何将 zsh 自动完成功能与包装函数参数和现有命令结合起来

我主要在 gvim 和许多终端中工作。最初，我更喜欢在单个 vim 实例中打开所有文件。为此，我使用别名从当前“vim 服务器”中的终端打开文件。

alias rv="gvim --remote-silent"

但是在单个 vim 实例中打开多个项目的许多文件会影响我的工作效率，因此我将别名升级为函数。

# main function
rv() {
    local args options server

    options=$(getopt -o hils:t: -l "help,info,list,set:,target:" -- "$@")

    if [[ $? -ne 0 ]]; then
        echo "Failed to parse options."
        return 1
    fi

    # a little magic, necessary when using getopt
    eval set -- "$options"

    # go through the options with a case and use shift to analyze one option at a time.
    while true; do
        case "$1" in
            -h|--help)
                echo "Usage: $0 [-hil] [--help] [--info] [--list]";
                echo "       $0 {-s | --set} <name> [<file1 file2...>]";
                echo "       $0 {-t | --target} <name>] <file1 file2...>";
                return 0;;
            -i|--info)
                gvim_show_info;
                return 0;;
            -l|--list)
                gvim_list_servers;
                return 0;;
            -s|--set)
                gvim_set_server_name ${2:u};
                shift 2;;
            -t|--target)
                server="$2";
                shift 2;;
            --)
                shift;
                break;;
        esac
    done

    if [[ "$#" -eq 0 ]]; then
        # if no files specified...
        if [[ -n "$server" ]]; then
            # throw error if --target option was specified.
            echo "Error!  --target requires one or more filenames."
            return 1;
        fi
    else
        # if files were specified...
        if [[ -n "$server" ]]; then
            # if --target was specified
            gvim_run_remote $server "$@"
        else
            gvim_run_remote $(gvim_get_default_server) "$@"
        fi
    fi

    return 0;
}

现在这个新的rv有它自己的选择。我可以用它来：

  • 列出可用的 vim 服务器 (-l --list)
  • 设置当前 shell 的默认 vim 服务器 (-s --set)
  • 显示默认的 vim 服务器 (-i --info)
  • 打开特定 vim 服务器中的文件 (-t --target)
  • 在默认 vim 服务器中打开文件：rv files...

但是，由于我使用的是函数rv而不是别名，因此我失去了以前喜欢的 zsh 完成功能。我已经阅读了有关创建完成功能 的内容，_rv它将显示rv的选项，但我想将我的完成选项与现有的 vim 完成选项结合起来。我知道rv's-s和vim's可能存在一些冲突-s，但我认为我可以使用--分隔符优雅地处理它。

太长了；那么，如何创建一个结合了和_arguments选项的完成脚本？如果可能的话，我更喜欢重用，而不是将其参数列表复制粘贴到._rv_vim_vim_rv

这是我的_rv。 更新于2014/6/10 16:10

#compdef rv

_rv() {
    typeset -A opt_args
    local alternatives

    alternatives=(
        'args:rv options:_rv_options'
        'files:file:_vim_files'
    )

    _alternative $alternatives && return 0

    return 1
}

_rv_options() {
    local arguments

    arguments=(
        '(-i -l -s -t --info --list --set --target)'{-h,--help}'[Print usage info.]'
        '(-h -l -s -t --help --list --set --target)'{-i,--info}'[Print default vim server. As stored in $GVIM_SERVER.]'
        '(-i -h -s -t --info --help --set --target)'{-l,--list}'[Print list of existing vim servers.]'
        '(-i -h -l -t --info --help --list --target)'{-s,--set}'[Set default vim server for the current shell.]:vim servers:_rv_vim_servers'
        '(-i -h -l -s --info --help --list --set)'{-t,--target}'[Open files in a particular vim server.]:vim servers:_rv_vim_servers'
        )

    _arguments -s -C $arguments && return 0

    return 1
}

_rv_vim_servers() {
    local -a servers
    servers=( ${(f)"$(_call_program servers vim --serverlist 2>/dev/null)"} )
    _wanted servers expl server compadd -M 'm:{a-z}={A-Z}' -a servers && return
}

# invoke the completion command during autoload
_rv "$@"

目前的行为

目前_rv完成将可用，但并不理想。

  • 当我输入 时rv <TAB>，我看不到 vim 选项。仅显示 rv 选项和文件路径。 _vim正在为我完成文件路径，万岁！
  • 当我输入 时rv -s <TAB>，我会看到 vim 服务器列表，还会显示文件路径。此时命令中不允许使用文件，并且不应出现在自动完成中。

预期行为

  • 当我输入 时rv <TAB>，我希望看到：1) rv 选项，2) vim 选项，3) 文件路径列表
  • 当我输入 时rv -s <TAB>，我希望看到：1) vim 服务器名称（由_rv_vim_servers.
  • 当我输入 时rv /valid/file/path/<TAB>，我希望只看到文件路径列表。既然_vim已经有了这个能力，我宁愿依赖它。

答案1

你可以猴子补丁_arguments扩展完成器的函数_vim：

#compdef rv

_rv_vim_servers() {
    local expl
    _wanted servers expl server \
        compadd -- ${(f)"$( _call_program servers vim --serverlist 2>/dev/null )"}
}

_rv() {
  autoload +X -Uz _arguments             # Load the function body.
  functions -c _arguments _rv_arguments  # Make a copy.

  # Replace the original function.
  _arguments() {
    # Call the original function with additional completions.
    _rv_arguments "$@" \
        '(-i -l -s -t --info --list --set --target)'{-h,--help}'[print usage info]' \
        '(-h -l -s -t --help --list --set --target)'{-i,--info}'[print default vim server as stored in $GVIM_SERVER]' \
        '(-i -h -s -t --info --help --set --target)'{-l,--list}'[print list of existing vim servers]' \
        '(-i -h -l -t --info --help --list --target)'{-s,--set}'[set default vim server for the current shell]:vim servers:_rv_vim_servers' \
        '(-i -h -l -s --info --help --list --set)'{-t,--target}'[open files in a particular vim server]:vim servers:_rv_vim_servers'
  }

  {
    _vim "$@"
  } always {
    functions -c _rv_arguments _arguments  # Restore the original.
    unfunction _rv_arguments               # Discard our copy.
  }
}

_rv "$@"

答案2

我发现 /usr/share/zsh/functions/Completion/Unix/_git 其中有一些关于此类别名的提示，并最终为别名定义了这些函数：

_git-ls () {
  # Just return the _git-ls-files autocomplete function
  _git-ls-files
}

然后，直接执行 compdef g=git。自动完成系统将看到您正在运行，例如 g ls 并使用 _git-ls 自动完成功能。

发现这里

相关内容