高斯映射图像

Question 1

笔记那：我也不知道我在画什么。:)

在 Asymptote 中绘制 3D 图像对于我的知识和我的计算机来说都是一个难题（它很弱）。

您可以添加mesh一个表面。您也可以分别绘制两个表面（可以在http://asymptote.ualberta.ca/）。

您必须对表面进行参数化才能使用该命令vectorfield。

我很高兴，如果最佳渐近线答题者当然有更好的解决方案。

这是我的尝试，此代码是用编译的asy -f png -render=8 <name file>.asy。


import graph3;
import palette;

currentprojection=orthographic(1,1,0.3);
currentlight.background = gray(.7);
//currentlight=nolight;

typedef triple newtriple(pair);
// https://en.wikipedia.org/wiki/Hyperboloid
newtriple f(real a, real b, real c)
{
  return new triple(pair k){
    real u=k.x,v=k.y;
    real x,y,z;
    x=a*cosh(v)*cos(u);
    y=b*cosh(v)*sin(u);
    z=c*sinh(v);
    return (x,y,z);
  };
}
triple F(pair z){ return f(1,1,1)(z); }

// Gauss map
triple g(pair z)
{
  real u=z.x, v=z.y;
  triple U=(-cosh(v)*sin(u),cosh(v)*cos(u),0);
  triple V=(sinh(v)*cos(u),sinh(v)*sin(u),cosh(v));
  return cross(U,V)/abs(cross(U,V));
}

// https://trecs.se/hyperboloidOfOneSheet.php
path3 vector(pair z) {
  real u=z.x, v=z.y;
  real a=1, b=1, c=1;
  real x,y,z;
  x=-b*c*cosh(v)^2*cos(u);
  y=-a*c*cosh(v)^2*sin(u);
  z=a*b*sinh(v)*cosh(v);
  return O--(-(x,y,z)/sqrt(x^2+y^2+z^2));
}

picture pic, pic1, pic2, pic3;
size(pic1,300);
size(pic2,300);

surface sf=surface(F,(0,-1.5),(2pi,1.5),40,Spline);
sf.colors(palette(sf.map(zpart),Rainbow()));
draw(pic1,sf,render(merge=true));
label(pic1,"$(\mathcal{H})$",(-1,2.2,2.7),dir(45));
add(pic1,vectorfield(vector,F,(0,-1.5),(2pi,1.5),10,0.5,red,render(merge=true)));
xaxis3(pic1,Label("$x$",EndPoint),0,3.5,Arrow3);
yaxis3(pic1,Label("$y$",EndPoint),0,3.5,Arrow3);
zaxis3(pic1,Label("$z$",EndPoint),0,3,Arrow3);
pair z=(pi/7,-0.5);
dot(pic1,"$P$",F(z),dir(90),black+5bp);
draw(pic1,Label("$N(P)$",EndPoint),shift(F(z))*vector(z),blue,Arrow3);

surface sg=surface(g,(0,-1.5),(2pi,1.5),20,Spline);
sg.colors(palette(sg.map(zpart),Rainbow()));
draw(pic2,sg,render(merge=true));
label(pic2,"$N\left(\mathcal{H} \right)$",(-.5,0.5,0.8),dir(45));
dot(pic2,Label("$\frac{1}{\sqrt{2}}$",blue),(0,0,1/sqrt(2)),dir(45),green+5bp);
xaxis3(pic2,Label("$x$",EndPoint),0,1.5,Arrow3);
yaxis3(pic2,Label("$y$",EndPoint),0,1.5,Arrow3);
zaxis3(pic2,Label("$z$",EndPoint),0,1,Arrow3);

add(pic,pic1.fit(),(0,0),20W);
add(pic,pic2.fit(),(0,0),20E);
draw(pic3,Label("$N$",MidPoint,LeftSide),(-20,0)--(20,0),Arrow);
add(pic,pic3.fit());
add(pic.fit(),Fill(gray(.7)));

或者

settings.render=8;
import graph3;
import palette;

currentprojection=orthographic(1,1,0.3);
currentlight.background = gray(.7);

typedef triple newtriple(pair);
// https://en.wikipedia.org/wiki/Hyperboloid
newtriple f(real a, real b, real c)
{
  return new triple(pair k){
    real u=k.x,v=k.y;
    real x,y,z;
    x=a*cosh(v)*cos(u);
    y=b*cosh(v)*sin(u);
    z=c*sinh(v);
    return (x,y,z);
  };
}
triple F(pair z){ return f(1,1,1)(z); }

// Gauss map
triple g(pair z)
{
  real u=z.x, v=z.y;
  triple U=(-cosh(v)*sin(u),cosh(v)*cos(u),0);
  triple V=(sinh(v)*cos(u),sinh(v)*sin(u),cosh(v));
  return cross(U,V)/abs(cross(U,V));
}

// https://trecs.se/hyperboloidOfOneSheet.php
path3 vector(pair z) {
  real u=z.x, v=z.y;
  real a=1, b=1, c=1;
  real x,y,z;
  x=-b*c*cosh(v)^2*cos(u);
  y=-a*c*cosh(v)^2*sin(u);
  z=a*b*sinh(v)*cosh(v);
  return O--(-(x,y,z)/sqrt(x^2+y^2+z^2));
}

size(9cm);

surface sf=surface(F,(0,-1.5),(2pi,1.5),40,Spline);
//sf.colors(palette(sf.map(zpart),Rainbow()));
draw(sf,RGB(0,153,216),render(merge=true));
label("$(\mathcal{H})$",(-1,2.2,2.7),dir(45));
add(vectorfield(vector,F,(0,-1.5),(2pi,1.5),10,0.5,red,render(merge=true)));
xaxis3(Label("$x$",EndPoint),0,3.5,Arrow3);
yaxis3(Label("$y$",EndPoint),0,3.5,Arrow3);
zaxis3(Label("$z$",EndPoint),0,3,Arrow3);
pair z=(pi/7,-1);
dot("$P$",F(z),dir(70),black+3bp);
draw(Label("$N(P)$",EndPoint,LeftSide),shift(F(z))*vector(z),blue,Arrow3);

transform3 t=shift(5*(Y-X));
surface sg=surface(g,(0,-1.5),(2pi,1.5),20,Spline);
sg.colors(palette(sg.map(zpart),Rainbow()));
draw(t*sg,render(merge=true));
label("$N\left(\mathcal{H} \right)$",t*(-.5,0.5,0.8),dir(45));
dot(Label("$\frac{1}{\sqrt{2}}$",blue),t*(0,0,1/sqrt(2)),dir(135),green+2bp);
draw(Label("$x$",EndPoint),t*((0,0,0)--(3,0,0)),Arrow3);
draw(Label("$y$",EndPoint),t*((0,0,0)--(0,3,0)),Arrow3);
draw(Label("$z$",EndPoint),t*((0,0,0)--(0,0,3)),Arrow3);

draw(Label("$N$",Relative(.5),N),subpath((0,0,0)--t*(0,0,0),0.4,0.6),Arrow3);

附加代码，

双曲抛物面：z = xy

settings.render=8;
import graph3;
import palette;

currentprojection=orthographic(1,0.2,1);
currentlight.background = gray(.7);
size(8cm,5cm,false);

// https://mathworld.wolfram.com/HyperbolicParaboloid.html
triple f(pair k){
    real u=k.x,v=k.y;
    return (u,v,u*v);
}

// Gauss map
triple g(pair z)
{
  real u=z.x, v=z.y;
  triple U=(1,0,v);
  triple V=(0,1,u);
  return cross(U,V)/abs(cross(U,V));
}
// https://trecs.se/hyperbolicParaboloid.php
path3 vector(pair z) {
  real u=z.x, v=z.y;
  return O--((-v,-u,1)/sqrt(u^2+v^2+1));
}

surface sf=surface(f,(-2,-2),(2,2),40,Spline);
sf.colors(palette(sf.map(zpart),Rainbow()));
draw(sf,render(merge=true));
add(vectorfield(vector,f,(-2,-2),(2,2),10,0.5,red,render(merge=true)));

xaxis3(Label("$x$",EndPoint),-3,3,Arrow3);
yaxis3(Label("$y$",EndPoint),-3,3,Arrow3);
zaxis3(Label("$z$",EndPoint),-3,4,Arrow3);

及其高斯图

// ...
surface sg=surface(g,(-2,-2),(2,2),40,Spline);
sg.colors(palette(sg.map(zpart),Rainbow()));
draw(sg,render(merge=true));

xaxis3(Label("$x$",EndPoint),-2,2,Arrow3);
yaxis3(Label("$y$",EndPoint),-2,2,Arrow3);
zaxis3(Label("$z$",EndPoint),-2,2,Arrow3);

Answer