☰

使用 awk 解析 AIX 的 lsuser 节格式输出

tag-icon • tag-icon text-processing awk aix
使用 awk 解析 AIX 的 lsuser 节格式输出

我正在创建一个简单的 awk 脚本来解析 AIX 的lsuser -f ALL输出并在一行中返回信息。输出示例如下所示。

root:
    id=0
    pgrp=something
    groups=something
    home=/
    shell=/usr/bin/csh
    auditclasses=general
    login=true
    su=false

到目前为止，这是我的代码：-

$1 ~ /[^=]:[ ]*$/ {sub(/:/,"",$1);printf $1" ";FS="="}
$1 ~ /login/         {printf $2" "}
$1 ~ /su/     {printf $2" "}
$1 ~ /account_locked/         {printf $2" "}
$1 ~ /time_last_login/     {print $2}

该脚本不能很好地处理某些 ID 不存在的字段，例如time_last_login因为某些用户之前可能未登录。示例如下。

root something ALL false 1360813178
**daemon staff ALL true sysadm1 something ALL false 1352015794**
sysadm2 staff ALL true 1352015794

sysadm1 行应该换成新行。我该如何解决？

答案1

您可以添加一个变量，例如，user当您到达该user:行时。因此如果它是设置在用户名之前打印换行符，否则不打印，并跳过 下的换行符打印time_last_login。

如果可能缺少一个或多个字段，您可能会使用一个数组并在用户的每次迭代后进行打印，并END{}在最后添加一个。

这样您就可以打印例如N/A缺失的字段。

或者使用数组来指定要打印的字段。

示例（两者都有）：

function prnt_user_data(arr, prnt) {
    printf("\nAlternative 1:\n")
    for (p in prnt) {
        printf("%s ", prnt[p] in arr ? arr[prnt[p]] : "N/A")
    }
    printf("\nAlternative 2:\n")
    printf(\
    "%s %s %s %s\n",
    "user"            in arr ? arr["user"] : "N/A",
    "su"              in arr ? arr["su"] : "N/A",
    "account_locked"  in arr ? arr["account_locked"] : "N/A",
    "time_last_login" in arr ? arr["time_last_login"] : "N/A" \
    );
    delete arr;
}

BEGIN {
    FS="=|[ \t]*"
    prnt_flds["01"]="user";
    prnt_flds["02"]="su";
    prnt_flds["03"]="account_locked";
    prnt_flds["04"]="time_last_login";
}
NF == 0 {next}
NF == 3 {
    user_data[$2]=$3;
}
NF == 1 && /:[ ]*$/{
    if("user" in user_data)
        prnt_user_data(user_data, prnt_flds)
    user_data["user"]=substr($1, 1, length($1) - 1);
}
END {
    if("user" in user_data)
        prnt_user_data(user_data, prnt_flds)
}

相关内容