☰

绘制 Reeb 叶子

tag-icon • tag-icon asymptote
绘制 Reeb 叶子

我正在尝试绘制里布叶理。到目前为止，我有下面的代码和图像。问题是一个表面稍微凸出到它前面的表面（通过最前面的表面）。它们应该完全嵌套在前一个表面内，就像弯曲的花盆一样。

settings.outformat="pdf";
settings.prc=false;
settings.render=4;


import graph;
import graph3;
import three;

size(12cm,0);

real rcutoff=.8;
real rinner=1;
real router=2;


currentprojection=orthographic(1,-2,1);
currentlight=(1,-1,0.5);

real f(pair z) {return 1/(1-abs(z)^2);}

// We change variables so that the unit cylinder x^2+y^2<1 gets mapped to the torus.
triple changevariables(triple X)
{ 
    return (
        (router+rinner*X.x)*cos(X.z),
        (router+rinner*X.x)*sin(X.z),
        rinner*X.y
    );
}


// g returns the location of a point on a ``paraboloid'' inside the unit cylinder with given angle and radius above the unit disk in the (x,y) plane.
triple g(pair p){
    real x=p.x*cos(p.y), y=p.x*sin(p.y);
    return (x,y,f((x,y)));
}


triple h(pair p){
    return changevariables(g(p));
}

real anglestep=10;

for (int z = 0; z <= 20; ++z) {
    draw(
         rotate(-anglestep*z,Z)*surface(
            h,
            (0,0),
            (rcutoff,2*pi),Spline
        ),lightgray+opacity(1)
    );
//  real zz=f((rcutoff,0));
//  triple cent=changevariables((0,0,zz));
//  draw(
//      rotate(-anglestep,Z)*
//      circle(c=cent, r=rcutoff,normal=(-router*sin(zz),router*cos(zz),0)),
//      white
//  );
}

在此处输入图片描述

如果我仅用不同的颜色绘制最后两个表面，也许问题会更加清楚：

在此处输入图片描述

答案1

这仅仅是由于使用贝塞尔曲面片对曲面进行数值近似。默认情况下，您有 10 个网格（或 10x10）。根据您的 PC，您可以根据这两个变量独立增加网格数量。在这里，我使用

draw(
     rotate(-anglestep*z,Z)*surface(
                                    h,
                                    (0,0),
                                    (rcutoff,2*pi),nu=16,nv=10,Spline
                                    ),lightgreen+opacity(1)
     );

看起来还不错。

相关内容