单个 Ubuntu SDK 是否可以针对具有单独布局的触摸和桌面？

Question

我知道触摸应用程序将在桌面上以相同的 UI 运行，但我想知道单个 Ubuntu SDK 应用程序在桌面模式下运行时是否可以拥有带有桌面风格 UI 元素的多窗口 UI，同时在触摸平台上运行时还提供单独的触摸 UI。

Answer 1

根据窗口大小更改布局的各个方面可以通过多种方式实现。最基本的是，您可以根据尺寸将属性设置为不同的值。这是一个最小示例，它绘制了一个灰色方块，如果您将窗口放大，该方块会变成橙色：

运行qmlscene path/to/file.qml

import QtQuick 2.0
import Ubuntu.Components 0.1

MainView {
    id: root
    width: units.gu(50)
    height: units.gu(50)

    Rectangle {
        id: hello
        color: parent.width > units.gu(60) ? UbuntuColors.orange : UbuntuColors.warmGrey
        anchors.fill: parent
    }
}

当然，如果你的应用程序有更复杂的元素，这可能会有点乏味。为了解决这个问题，Ubuntu 工具包提供了一个ConditionalLayout 组件您可以在其中定义不同的布局，这些布局将在满足条件时激活。这是动态发生的，您可以在调整窗口大小时看到变化。

下面是一个更复杂的例子，使用ConditionalLayout：

import QtQuick 2.0
import Ubuntu.Components 0.1
import Ubuntu.Components.ListItems 0.1 as ListItem
import Ubuntu.Layouts 0.1

MainView {
    id: root
    width: units.gu(50)
    height: units.gu(75)

    Page {
        anchors.fill: parent

        Layouts {
            id: layouts
            anchors.fill: parent
            layouts: [

                ConditionalLayout {
                    name: "flow"
                    when: layouts.width > units.gu(60)

                    Flow {
                        anchors.fill: parent
                        flow: Flow.LeftToRight

                        ItemLayout {
                            item: "sidebar"
                            id: sidebar
                            anchors {
                                top: parent.top
                                bottom: parent.bottom
                            }
                            width: parent.width / 3
                        }

                        ItemLayout {
                            item: "colors"
                            anchors {
                                top: parent.top
                                bottom: parent.bottom
                                right: parent.right
                                left: sidebar.right
                            }
                        }
                    }
                }
            ]

            Column {
                id: sidebar
                anchors {
                    left: parent.left
                    top: parent.top
                    right: parent.right
                }
                Layouts.item: "sidebar"

                ListItem.Header {
                    text: "Ubuntu Color Palette"
                }

                ListItem.Standard {
                    id: orangeBtn
                    text: "Ubuntu Orange"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.orange
                        }
                    }
                }

                ListItem.Standard {
                    id: auberBtn
                    text: "Canonical Aubergine"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.lightAubergine
                        }
                    }
                }

                ListItem.Standard {
                    id: grayBtn
                    text: "Warm Grey"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.warmGrey
                        }
                    }
                }
            } // Column

            Rectangle {
                id: hello
                Layouts.item: "colors"
                color: UbuntuColors.warmGrey
                anchors {
                    top: sidebar.bottom
                    bottom: parent.bottom
                    left: parent.left
                    right: parent.right
                }

                Label {
                    anchors.centerIn: parent
                    text: "Hello (ConditionalLayout) World!"
                    color: "black"
                    fontSize: "large"
                }
            }
        } // Layouts
    } // Page
} // Main View

当采用默认手机尺寸时，它看起来像：

当它扩展到平板电脑或桌面大小时，它看起来像：

Answer 2

我认为你可以使用以下方法获得此结果条件布局。