☰

tcsh 在命令替换 `...` 中保留换行符

tag-icon • tag-icon tcsh command-substitution
tcsh 在命令替换 `...` 中保留换行符

因此，我编写了一个简单的脚本将sh-styleexport key=value语句转换为csh-style setenv key valuefor docker-machine env。

#!/bin/sh
docker-machine env | sed -e 's/export/setenv/' -e 's/=/ /' -e '$d'
echo '# eval `docker-machine env`'

它产生以下输出

setenv DOCKER_TLS_VERIFY "1"
setenv DOCKER_HOST "tcp://<ipv4 address>:<port>"
setenv DOCKER_CERT_PATH "<HOME>/.docker/machine/machines/default"
setenv DOCKER_MACHINE_NAME "default"
# Run this command to configure your shell:
# eval `docker-machine env`

在我的文件中.tcshrc，我已将此脚本绑定到 alias docker-machine-env-csh。

我可以使用临时变量来获取该脚本的输出

% docker-machine-env-csh >! /tmp/csh && source /tmp/csh

但是，我似乎无法直接得到eval这个别名的结果

% eval `docker-machine-env-csh`
setenv: Too many arguments.

或者以保留换行符的方式将其分配给变量。

% set a = `docker-machine-env-csh`
% printf "%s\n" "$a"
setenv ... setenv ... setenv ...

虽然，奇怪的是printf "%s\n" `docker-machine-env-csh`似乎在每个标记之间插入换行符。

% printf "%s\n" `docker-machine-env-csh`
setenv
...
...
setenv
...
...

如何在tcsh命令替换中保留换行符？

答案1

有很多充分的理由说明为什么建议不要使用csh或tcsh来编写脚本。这就是其中之一。

要将some command逐字输出放入 shell 变量中tcsh，您需要类似以下内容：

set temp = "`(some command; echo .) | paste -d . - /dev/null`"
set var = ""
set nl = '\
'
foreach i ($temp:q)
  set var = $var:q$i:r:q$nl:q
end
set var = $var:r:q

不要忘记使用$var:q语法来扩展变量，如下所示：

printf '<%s>\n' $var:q

POSIXsh等效项是：

var=$(some command; echo .)
var=${var%.}

现在，如果您的docker-machine-env-csh命令确实仅在一行上输出信息，或者至少每行都以 a 结尾;且没有注释，这样当与空格连接时，它们仍然是有效的 csh 代码（就像应用程序，例如dircolors或ssh-agentdo 当它们想要输出时传递给cshs eval)，那么你可以这样做：

set var = "`docker-machine-env-csh`"
printf '%s\n' "$var"
# or printf '%s\n' $var:q
# or printf '%s\n' "$var:q"

使用set var = `docker-machine-env-csh`,tcsh在空格上分割（并创建一个数组变量），而使用set var = "`docker-machine-env-csh`", 它仅在换行符上分割（仍然是一个数组变量，但如果输出只有一行，则该数组只有一个元素）。

这里你可以使用"$var"of 来代替，$var:q因为$var不包含换行符。"$var"会用空格连接数组元素，而$var:q会保留它们（这里只有一个元素，所以没有区别）。如果这些数组元素可能包含换行符并且您想用空格将它们连接起来，则可以使用"$var:q".

所以也许你可以修改你的脚本，例如：

#! /bin/sh -
docker-machine env | sed '
  s/export/setenv/
  s/=/ /
  /^#/!s/$/;/
  $d'
echo '# eval "`docker-machine env`"'

相关内容