☰

如何在演示时更新 PowerPoint 幻灯片

tag-icon • tag-icon microsoft-powerpoint microsoft-powerpoint-2010
如何在演示时更新 PowerPoint 幻灯片

我需要找到一种方法，根据观众的反馈在演示过程中用图像更新 PowerPoint 幻灯片（即观众对图像进行投票，然后该图像稍后被放到幻灯片上）。

我担心在演示模式下进行编辑的风险以及编辑器在演示过程中无意中退出幻灯片放映。

是否有任何附加组件等可用于 PowerPoint 中途编辑/修改幻灯片，同时尽可能避免弄乱现场演示的风险？

迄今为止的想法：

  • 使用 LiveWeb 插件和 FTP 站点/Dropbox 指向图像并根据观众反馈覆盖 LiveWeb 幻灯片上的图像（对于现场执行此操作的编辑者来说太复杂了）
  • 在共享网络上远程更新演示文稿（不确定 PPT 是否会实时更新）。
  • 更新：只要演示文稿使用“演示者视图”和扩展显示器，您就可以浏览整个计算机并编辑 PowerPoint 上的任何幻灯片。编辑后的幻灯片将显示实时演示文稿中更新的内容/图像。但是，这样做会暂停实时演示文稿。因此，如果演示者需要在您编辑时转到下一张幻灯片或激活动画，则在演示文稿恢复之前不会发生这种情况。只要演示者在编辑器完成编辑之前不尝试移动到下一张幻灯片，这似乎就可以工作。是否有允许同时编辑和导航演示文稿的插件？

以前有人做过类似的事情吗？你是如何让它在现场演示中发挥作用的？

答案1

在 PowerPoint 2013 中，这确实非常简单：

  1. 在演示者视图中，单击“显示任务栏”（左上角）

  2. 当屏幕底部的任务栏打开时，单击 PowerPoint 选项卡，

  3. 在显示的三个视图（编辑器、演示者和幻灯片）中，单击编辑器视图。

  4. 如果您希望观众能够看到您所做的更改，请在所有 3 个视图中显示相同的幻灯片。

  5. 如果您不想让观众在您完成之前看到更改，请在开始更改之前单击演示者视图（带有对角线的监视器）中的黑屏图标，或者在演示者视图中更改为不同的幻灯片。

  6. 当您进入幻灯片放映时，它将在大屏幕上显示您更改的幻灯片。

快乐地使用 PowerPoint！

答案2

MDT 比他想象的更接近现实；我曾经简要介绍过一堆演示文稿，其中一些演示文稿在演出期间正在编辑。关键是要创建主演示文稿作为演示文稿集合的流畅界面。我曾经在 Office 97 中完成这项工作；我相信现在可以做到。如果这适合您的需求，那么静态链接到易变的演示文稿（但具有稳定的文件名）可能就是最好的选择。

答案3

这实际上非常简单，特别是当您说您想更改当前不在视图中的幻灯片时（由于某些 PPT 版本中的错误，这可能会变得棘手）。

将其添加到演示文稿中的 VBA 模块。
您必须将演示文稿保存为 PPTM 或 PPSM，而不是 PPTX/PPTX。

按照注释中包含的说明进行操作：

Option Explicit

' We'll modify slide #4 ... change as needed
' Make sure that the slide has no empty content or picture placeholders on it
Const lSlideNum As Long = 4

Sub AddAnImage()
    ' add a shape to any slide you like
    ' assign the shape an Action Setting of Run Macro: AddAnImage

    Dim oSl As Slide
    Dim oSh As Shape

    Set oSl = ActivePresentation.Slides(lSlideNum)

    ' bring in the image; setting width/height to -1 ensures that you
    ' don't distort it
    Set oSh = oSl.Shapes.AddPicture("c:\temp\photo.jpg", msoFalse, msoTrue, 0, 0, -1, -1)

    With oSh
        .LockAspectRatio = msoTrue ' to make sure it stays undistorted
        ' change its position/size as you wish
        ' for example, let's make it the full width of the slide:
        .Width = ActivePresentation.PageSetup.SlideWidth
    End With

End Sub

答案4

Option Explicit

' We'll modify slide #4 ... change as needed ' Make sure that the slide has no empty content or picture placeholders on it Const lSlideNum As Long = 4

Sub AddAnImage()
    ' add a shape to any slide you like
    ' assign the shape an Action Setting of Run Macro: AddAnImage

    Dim oSl As Slide
    Dim oSh As Shape

    Set oSl = ActivePresentation.Slides(lSlideNum)

    ' NEW:  Delete any existing image we may have added previously
    On Error Resume Next
    Set oSh = oSl.Shapes("MagicImage")
    If Err.Number = 0 Then
       oSh.Delete
    End If

    ' bring in the image; setting width/height to -1 ensures that you
    ' don't distort it
    Set oSh = oSl.Shapes.AddPicture("c:\temp\photo.jpg", msoFalse, msoTrue, 0, 0, -1, -1)

    With oSh
        ' NEW:  Name it so we can locate it easily later:
        .Name = "MagicImage"
        .LockAspectRatio = msoTrue ' to make sure it stays undistorted
        ' change its position/size as you wish
        ' for example, let's make it the full width of the slide:
        .Width = ActivePresentation.PageSetup.SlideWidth
    End With

End Sub

相关内容