☰

如何使用 cmd 行提升我的 cmd 提示符

tag-icon • tag-icon windows windows-8 command-line batch-file shell-script
如何使用 cmd 行提升我的 cmd 提示符

我按照这个脚本“runas /profile /user:administrator\administrator cmd”当它提示我输入密码时，它总是说密码不正确，尽管我拼写正确。请帮帮我，我正在尝试为学校编写一个批处理脚本，但这就是我遇到的全部问题。

答案1

就像 Wes Sayeed 已经解释的那样，您无法在 Windows 中提升正在运行的程序。但是（即使对您来说为时已晚）这里解决方案是使用一种嵌入式 VBS 以管理员权限重新启动命令提示符：

@echo off

:checkPrivileges
NET FILE 1>NUL 2>NUL

if '%errorlevel%' == '0' (
  goto mainScript 
) else (
  goto getPrivileges
)
::-------------------------------------------------------------------------------------------------

:getPrivileges
  if '%1'=='ELEV' (shift & goto mainScript)
  echo.
  echo Selbstausfuehrung mit Administratorrechten...
  setlocal DisableDelayedExpansion
  set "batchPath=%~0"
  setlocal EnableDelayedExpansion
  echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\runAsAdmin.vbs"
  echo UAC.ShellExecute "!batchPath!", "ELEV", "", "runas", 1 >> "%temp%\runAsAdmin.vbs"
  "%temp%\runAsAdmin.vbs"
  exit /B
::-------------------------------------------------------------------------------------------------


:mainScript
REM Here we are doing admin stuff...
  cls
  echo Hallo Welt >C:\test.txt

答案2

即使您提供了管理员凭据，runas 命令也无法用于提升命令提示符。无法从未提升的命令提示符中提升命令提示符。

相关内容