Excel 公式 - 根据查看两个单独的值（任一/或）返回值

Question

我正在使用这个公式从下表中返回一个值：

=IF(ISNA(VLOOKUP(A2,USUB,1,FALSE)),"No Fruit Found",VLOOKUP(A2,USUB,2,FALSE))

USUB 表包含以下数据：

Fruit          Fruit Code   FruitID Location          CITY
Apple             APP          A    SEATTLE,WA          SEATTLE
Bananas           BAN          B    MODESTO,CA          MODESTO
Cherry            CHER         C    CHARLESTON,SC       CHARLESTON
Blackberrires     BLCKB        D    VICKSBURG,VA        VICKSBURG
Blueberries       BLUB         E    SAN DIEGO,CA        SAN DIEGO
Cantaloupe        CANT         F    GULF SHORES, AL     GULF SHORES
Grapes            GRP          G    NAPA VALLEY,CA      NAPA VALLEY
Peach             PCH          H    ATLANTA, GA         ATLANTA
Grapefruit        GRPFRT       I    FT LAUDERDALE, FL   FT LAUDERDALE
Pomegranate       POM          J    HONOLULU, HI        HONOLULU
Kiwi              KIW          K    SALEM, OR           SALEM

---

我应该使用什么公式首先查看水果（USUB,1），然后查看位置（USUB,4），并根据公式中的标准返回水果代码（USUB,2）的值？

Answer 1

我很少建议使用差分对接功能，但这是一个可以充分发挥它作用的完美示例。请参阅下图了解设置和使用

公式为：

=DGET(USUB,"Fruit Code",$A$1:$B$2)

它甚至还有一个额外的好处，如果你不输入位置，它就会找到该水果的代码。

要捕捉没有匹配的水果和位置组合的情况，请参见下文：

=IFERROR(DGET(USUB,"Fruit Code",$A$1:$B$2),"Not found")

Answer 2

您可以使用具有多个条件的 Index/Match，以数组形式输入（使用CTRL+SHIFT+ENTER：

=INDEX($C$2:$C$13,MATCH(H3&I3,$B$2:$B$13&$E$2:$E$13,0))

（根据需要调整）

因此，我能够使用水果代码和位置来返回 ID。公式正确解析为J。这是您想要的吗？您基本上只需将Match()条件与链接起来&，然后将要匹配的范围与链接起来&，然后作为数组输入。

Answer 3

这将首先查看是否存在重复，如果没有，它将返回正确的 ID，无论输入的位置是什么。

如果有多个这种水果，系统就会到该位置寻找匹配的水果。

如果在任何一种情况下都找不到匹配项；要么是水果不存在，要么是水果和位置的组合（当有多个水果时）不正确。

=IF(COUNTIF(A:A,H2)>1,IFERROR(INDEX($C$2:$C$13,MATCH(1,INDEX(($D$2:$D$13=I2)*($A$2:$A$13=H2),),0)),"Multiple fruits but Location is wrong"),IFERROR(INDEX(C:C,MATCH(H2,A:A,0)),"Not Found"))

对于表格的引用，请使用以下命令：

=IF(COUNTIF(USUB[Fruit],H2)>1,IFERROR(INDEX(USUB[FruitID],MATCH(1,INDEX((USUB[Location]=I2)*(USUB[Fruit]=H2),),0)),"Multiple fruits but Location is wrong"),IFERROR(INDEX(USUB[FruitID],MATCH(H2,USUB[Fruit],0)),"Not Found"))