☰

在 Excel 中创建从第一个输入数字到第二个输入数字的数字序列

tag-icon • tag-icon microsoft-excel
在 Excel 中创建从第一个输入数字到第二个输入数字的数字序列

我想在消息框中写出我选择的两个数字之间的数字。同时检查它们是否为偶数，并且它们必须从最小数到最大数。这两个数字必须是正数并且小于 100。

我在 Excel 中使用 Visual Basic，但我以前从未使用过它。

Private Sub CommandButton1_Click()

Dim a, b, P, i As Integer

a = InputBox("Write number from 1 to 100 ")
If a <= 0 Or a >= 100 Then
MsgBox "Wrong input"
Exit Sub
End If
b = InputBox("Write number from 1 to 100 ")
If b <= 0 Or b >= 100 Then
MsgBox "Wrong input"
Exit Sub
End If

For i = a To b
If a <> 0 & a <= b Then
a = a + 1
Else
P = a
a = a + 1
Exit For
End If
Next i

MsgBox P


End Sub

答案1

我会做些不同的事情。您当然可以使用 command_button 触发此操作。请注意，我会检查偶数（并且我不会将零视为正数（或负数）。

Option Explicit
Sub CreateSequence()

   'Note each variable must have a type declaration,
   '   else they will be of type Variant
    Dim x As Long, y As Long, z As Long
    Dim S As String

x = InputBox("First Number")
y = InputBox("Second Number")

If Not CheckNum(x) Or Not CheckNum(y) Then
        MsgBox "Both numbers must be positive and less than 100"
        Exit Sub
    End If

If x > y Then 'reverse x and y
    z = y
    y = x
    x = z
End If

For z = x To y
    'check if even and add to string if they are
    If z Mod 2 = 0 Then S = S & vbLf & z
Next z

'Remove the leading separator (vbLf)
S = Mid(S, 2)

MsgBox S

End Sub

Function CheckNum(L As Long) As Boolean
    If L > 0 And L < 100 Then
        CheckNum = True
    Else
        CheckNum = False
    End If

End Function

相关内容