☰

添加带有日期的单元格

tag-icon • tag-icon microsoft-excel worksheet-function
添加带有日期的单元格

在此处输入图片描述

我正在尝试对日期范围之间的单元格范围进行求和，即第 n 列包含金额，第 d 列包含交易日期，即 2015 年 3 月 1 日或 2015 年 3 月 25 日或 2015 年 4 月 25 日，第 b 列包含文字 drp 或 distribution - reinv

在另一个单元格中，我尝试对包含不同文本（b 列）的不同日期范围（d 列）的值进行求和或总计（在 n 列中），即单元格 n48 为 50，n65 为 85，n165 为 36

带有日期，即单元格 d48 为 1/3/2015、d65 为 25/3/2015 和 d165 为 25/4/2015

使用不同的文本表示 drp 或 distribution - reinv 即单元格 b48 是 drp，b65 是 distribution - reinv，b165 是 drp

如果我想计算 2015 年 1 月 3 日至 2015 年 3 月 31 日之间使用 drp 的金额总和，那么总数将是 50。另外，如果我想计算 2015 年 1 月 4 日至 2015 年 4 月 30 日之间使用 drp 的金额总和，那么总数将是 36。如果我想计算 2015 年 1 月 3 日至 2015 年 3 月 31 日之间使用 drp 和 distribution - reinv 的金额总和，那么总数将是 115

这些不同问题的公式是什么

希望你能帮忙，这让我很抓狂，无法解决

答案1

就像 Michthan 所说的那样，数据透视表可以做到这一点，但对于从未使用过数据透视表的人来说，这可能会令人望而生畏。然而，SUMIFS()函数正是您在这种情况下所需要的：

场景 1：

=SUMIFS($N:$N,$B:$B,"drp",$D:$D,">="&DATE(2015,3,1),$D:$D,"<="&DATE(2015,3,31))

场景 2：

=SUMIFS($N:$N,$B:$B,"drp",$D:$D,">="&DATE(2015,4,1),$D:$D,"<="&DATE(2015,4,30))

场景 3：

=SUM(SUMIFS($N:$N,$B:$B,{"drp","distribution - reinv"},$D:$D,">="&DATE(2015,3,1),$D:$D,"<="&DATE(2015,3,31)))

虽然这些公式完全可以满足您所述的条件（您可以随意编辑公式中的日期），但如果您想更改条件，它们就不太灵活。最好将您的条件保留在某些单元格中，例如 $O$1:$O$4，并在公式中引用这些单元格，如下所示：

$O$1 = drp [text]
$O$2 = 1/3/2015 [start date]
$O$3 = 31/3/2015 [end date]

公式就变成

=SUMIFS($N:$N,$B:$B,$O$1,$D:$D,">="&$O$2,$D:$D,"<="&$O$3)

附注：我无法让带有单元格引用的多个 OR() 文本条件起作用，即使在 INDIRECT() 函数中也是如此。如果有人可以提供更多指导，我相信 Murray 会很感激。

相关内容