☰

在文本中添加数字

tag-icon • tag-icon microsoft-excel worksheet-function macbook
在文本中添加数字

我有包含数字和文本的单元格，并且我只想对单元格末尾的数字求和。这是我的单元格的一个示例：

L4-R4

L8-R9

L11-R11

L12-R11

L12-R11

L9-R9

答案是：L56-R55

之后，我想在另一张工作表上更新答案。假设我的单元格位于 Sheet1 上的 F80 到 F89，那么答案位于同一张工作表 (Sheet1) 上的 F90。现在我想在 Sheet 2 上（例如 B1）也更新答案 (F90)。如何在 Mac 电脑上执行这些操作？

谢谢！！

答案1

辅助列

解决此类问题最快的方法通常是使用辅助列来分解问题。为了对数字部分进行计算，我提取了数字。

在此处输入图片描述

您可以从 的位置获得所有事物的位置R。在 B 列中，我提取了 L 编号。B1：

=MID(A1,2,FIND("R",A1)-3)*1

MID 提取从第二个字符开始的字符，长度为 R 位置减 3（即减去L、-和R）。该字符被提取为字符串，因此乘以1会将其变成数字。

R 编号在 C 列。C1：

 =MID(A1,FIND("R",A1)+1,LEN(A1))*1

在这种情况下，MID 从 R 之后的位置开始，并获取字符串的其余部分。字符数指定为 A1 值的整个长度，但 Excel 在到达字符串末尾时用尽了字符。

获取 R 数的另一种方法是 Rajesh S 的回答中使用的方法：

=REPLACE(A1,1,FIND("R",A1),"")*1

这会将数字左侧的所有字符（从第一个到 ）替换R为空。同样，*1将结果转换为数值。

A8 中的结果是通过使用&连接各部分构建新字符串并插入辅助列总和生成的：

="L" & SUM(B1:B6) & "-R" & SUM(C1:C6)

如果不想让辅助列可见，您可以隐藏它们或将它们粘到不妨碍的地方。

无辅助列

一旦您弄清楚了如何使用辅助列，通常就可以通过在数组样式计算中使用公式来消除辅助列。SUMPRODUCT 可让您使用常规公式做到这一点；它计算范围内每个值的结果，然后将它们相加。L 值的总和可以直接使用以下方法完成：

=SUMPRODUCT(--(MID(A1:A6,2,FIND("R",A1:A6)-3)))

这是用于辅助列的相同公式，但单个单元格引用被替换为数据范围。这也说明了将文本结果转换为数字的另一种方法；*1它使用双重否定而不是将结果视为数字，同时保持其符号不变。

类似地，对于 R 数，我将使用替代公式，因为它更短一些：

=SUMPRODUCT(--(REPLACE(A1:A6,1,FIND("R",A1:A6),"")))

这些公式无需辅助列即可为您提供总和。您可以使用这些总和（而不是使用辅助列结果的SUM(B1:B6)和）在单个单元格中构建最终结果：SUM(C1:C6)

="L" & SUMPRODUCT(--(MID(A1:A6,2,FIND("R",A1:A6)-3))) & "-R" & SUMPRODUCT(--(REPLACE(A1:A6,1,FIND("R",A1:A6),"")))

另一张纸上的动态答案

要将自动更新的结果复制到另一张工作表上，只需在该显示单元格中输入对原始结果的引用。在单元格引用中包含工作表名称，并用感叹号连接。要引用 Sheet1 的单元格 A8 中的结果，单元格引用应为=Sheet1!A8。

创建单元格引用的快速方法是输入=显示单元格，然后在点击 之前Enter，转到第一个工作表并单击结果单元格。Excel 将为您填写单元格引用。

答案2

要解决此问题，您需要在辅助列中输入值：

在此处输入图片描述

怎么运行的：

  • 单元格中的公式B90：

=LEFT(A90,FIND("-",A90)-1)

  • 单元格中的公式C90：

=REPLACE(A90,1,FIND("-",A90),"")

填写两个公式。

  • 在单元格中输入此数组公式B96，最后Ctrl+Shift+Enter。

{=SUM(--SUBSTITUTE(B90:B95,"L",""),B90:B95)}

  • 单元格中的数组公式C96，也用Ctrl+Shift+Enter。

{=SUM(--SUBSTITUTE(C90:C95,"R",""),C90:C95)}

  • 单元格中的最终公式D96：

="L"&B96&"-"&"R"&C96

根据需要调整公式中的单元格引用。

相关内容