%20%E7%9A%84%E5%85%AC%E5%BC%8F%E4%B8%AD%E6%8B%92%E7%BB%9D%20CHOOSECOLS(Array%2CColnum)%EF%BC%9F.png)
概括
有人能解释一下为什么 Excel（Mac 和 Windows 上的当前版本）有时拒绝接受单元格公式中的以下内容：
CHOOSECOLS(SomeArray,ColNum)
但它确实接受了这一点：
INDEX(SomeArray,0,ColNum)
两个具体的例子是当这些形式在 SUMIF() 或 COUNTIF() 函数中使用时。当我说 Excel 拒绝接受前者时，我的意思是我甚至无法让它接受它作为语法正确的公式。我注意到这些函数的非条件版本不是显示问题，MAX()、MIN()、AVERAGE() 等函数也不显示问题。
细节
假设我在 B5:C10 中有一个数组（假设它是动态的，因此在以下示例中我可以将其整齐地引用为 B5#；但即使在非动态范围中也存在此问题），并且我想对第 2 列（即 C5:C10）中所有大于 0 的项目求和。而 Excel 接受以下内容：
=SUMIF(INDEX(B5#,0,2),">0")
它拒绝接受：
=SUMIF(CHOOSECOLS(B5#,2),">0")
但是，如果我首先将所需的列提取到以 C16 为根的辅助数组中（比如说），如下所示：
=CHOOSECOLS(B5#,2)
那么以下内容将被接受为正确公式（并且它给出了正确的结果）：
=SUMIF(C16#,">0")
我有一张 Excel 表格，上面显示了此操作，但我不确定附加它的最佳方法。如果它有用，并且有人可以解释如何附加 .xlsx 文件，我会提供它。同时，这是一张屏幕截图：
答案1
SUMIF您列出的其他函数是所谓的 RACON 函数，需要范围输入。（您可以阅读更多相关信息这里）
说实话，它与 INDEX 配合使用让我有点惊讶，但我猜 Excel 仍然将其解释为范围输入。如果您使用=SUMIF(INDEX(B5#,{1;2},2),">0")它，它将不再被接受为范围，但它被识别为数组，这不是可接受的输入。
我们可以通过研究不限于范围输入的其他 Excel 函数（例如 MMULT）来绕过此问题。虽然它比 SUMIFS 稍微不那么简单，但让我尝试解释一下逻辑：
MMULT用途米亚特里克斯乘数含义。如果你有 2 个矩阵：
MMULT 将把矩阵 1 的第一行与矩阵 2 的转置第一列值相乘：
={1,2,3}*{10;20;30}
这些乘积的总和就是第一个 MMULT 结果：10+40+90= 140
接下来，它将矩阵 1 的第一行值与矩阵 2 的下一个转置列相乘：
={1,2,3}*{4;5;6}=4+10+18= 32
接下来将矩阵 1 的第二行与矩阵 2 的第一个转置列相对应：
={4,5,6}*{10;20;30}=40+100+180= 320
最后将矩阵 1 的第二行与矩阵 2 的第二个转置列相对应：
={4,5,6}*{4;5;6}=16+25+36= 77
其结果是：
更加直观：
我为什么要讲这个？
SUMIFS不能将数组作为范围参数，但 MMULT 可以，并且我们可以使用与 MMULT 内部的 SUMIFS 类似的逻辑，我们只需要将其乘以与输入数组的宽度（列数）相同的高度（行数）的数组。
因此，返回B5#并将 SUMIFS 参数转换为 MMULT 将是：
=MMULT(TOROW(CHOOSECOLS(B5#,2)),N(CHOOSECOLS(B5#,2)>0))
或
=LET(b,CHOOSECOLS(B5#,2),MMULT(TOROW(b),N(b>0)))
它将的值转置CHOOSECOLS(B5#,2)到一行并将它们乘以一个垂直的布尔数组（CHOOSECOLS(B5#,2)值大于 0 TRUE 或 FALSE），其中 TRUE 和 FALSE 分别转换为它们的数字表示1和0。
然后将其相加。
但在这种情况下，我们也可以使用 SUM 内的布尔值：
=LET(b,CHOOSECOLS(B5#,2),SUM(b*(b>0)))
那为什么还要费心去解释 MMULT 呢？
因为 MMULT 还具有溢出结果数组的能力：
因此，在您的情况下，如果我们要按行对大于 0 的值求和，我们要么手动拖动 SUM 版本，要么使用 BYROW LAMBDA 版本，但 MMULT 可以完美地一次性完成，无需手动拖动：
=MMULT((B5#>0)*B5#,{1;1})将会泄漏：
或 COUNTIF 等效项：
=MMULT(N(B5#>0),{1;1})
答案2
只需嵌套几个 Take() 函数。我认为在这些函数（Sumif、Sumifs、Countif 和 Countifs）中，最简单的 Choosecols 解决方法是嵌套 Take 函数来替换 Choosecols。
如果您需要 4 列动态范围中的第 3 列，则 Take(Take(range#,,3),,-1) 将仅返回第三列作为范围。
Take(Take(range#,,3),,-1)