从文档中去除所有 LaTeX 代码的最有效方法是什么？

Question 1

以下是一个小perl脚本，可以帮助您入门。您可以将其用作

 perl removelatexcode.pl myfile.tex myfile1.tex

并且可以根据需要用任意数量的文件来调用它（或者您也可以通过管道将其输入到其中）。

它执行以下操作：

复制你的输入文件，myfile.tex以防myfile.tex.bak万一出现问题
循环遍历文件中的每一行，并且只有当遇到\begin{document}
一旦它进入主文档，它就会匹配诸如\begin{<myenvironmentname>}、之类的模式\end{environmentname}，\<name of command>您可以根据需要向其中添加内容。

代码不会覆盖原始文件。一旦你对它感到满意，已经测试过了根据你的喜好，随意使用该文件作为

 perl removelatexcode.pl -o myfile.tex

哪个将覆盖myfile.tex。

使用此类脚本时务必小心- 这里没有恶意，但是在实时文件上使用它之前，你应该进行彻底的测试。

例如，如果您希望保留某些命令的参数，\underline{keep this argument}则只需填充

my %keeparguments=("textit"=>1,
                        "underline"=>1,
                        );

使用适当的命令。

removelatexcode.pl

#!/usr/bin/perl 

use strict;
use warnings;
use File::Copy;
use Getopt::Std;

# get the options
my %options=();
getopts("o", \%options);


my $inpreamble=1; # switch for in the preamble or not
my $filename;
my @lines=();     # @lines: stores the new lines without commands

# commands for which we want to keep the arguments- populate 
# as necessary
my %keeparguments=("textit"=>1,
                        "underline"=>1,
                        );

while (@ARGV)
{
      # get filename from arguments
      $filename = shift @ARGV; 

      # open the file
      open(INPUTFILE,$filename) or die "Can't open $filename";

      # reset the preamble switch
      $inpreamble=1;

      # reset the lines array
      @lines=();     

      # loop through the lines in the INPUT file
      while(<INPUTFILE>)
      {
          # check that the document has begun
          if($_ =~ m/\\begin{document.*/)
          {
              $inpreamble=0;   
          }
          # ignore the preamble, and make string substitutions in 
          # the main document
         if(!$inpreamble) 
         {
             # remove \begin{<stuff>}[<optional arguments>]
             s/\\begin{.*?}(\[.*?\])?({.*?})?//g;
             # remove \end{<stuff>}
             s/\\end{.*?}//g;
             # remove \<commandname>{with argument}
             while ($_ =~ m/\\(.*?){.*?}/)
             {
                if($keeparguments{$1})
                {
                  s/\\.*?{(.*?)}/$1/;
                }
                else
                {
                  s/\\.*?{.*?}//;
                }
             }
             # print the current line (if we're not overwritting the current file)
             print $_ if(!$options{o});
             push(@lines,$_);
         }
     }

     # close the file
     close(INPUTFILE);

     # if we want to over write the current file
     if ($options{o})
     {
         # make a backup of each file
         my $backupfile= "$filename.bak";
         copy($filename,$backupfile);

         # reopen the input file to overwrite it
         open(INPUTFILE,">",$filename) or die "Can't open $filename";
         print INPUTFILE @lines;
         close(INPUTFILE);

         # output to terminal
         print "Backed up original file to $filename.bak\n";
         print "Overwritten original file without commands";
     }
}

exit

这是一个小测试用例：

myfile.tex

\documentclass{article}
% in the preamble
% in the preamble
% in the preamble
\begin{document}

\begin{myenvironment}
  text text text text text text text text text text 
  text text text text text text text text text text 
  text text text text text text text text text text 
  text text text text text text text text text text 
\end{myenvironment}

\mycommand{argument} more text after it \anothercommand{another argument}

\textit{keep this argument} more text after it \anothercommand{another argument} yet more text

\anothercommand{another argument} yet more text \textit{keep this argument} more text after it 

\begin{anotherenvironment}[optional arguments] could have text here
  other other other other other other other other other other 
  other other other other other other other other other other 
  other other other other other other other other other other 
  other other other other other other other other other other 
\end{anotherenvironment}

\begin{anotherenvironment}[optional arguments]{mandatory args} could have text here
  another another another another another another 
  another another another another another another 
  another another another another another another 
  another another another another another another 
\end{anotherenvironment} can have text here

\end{document}

以及输出

perl removelatexcode.pl myfile.tex

输出

  text text text text text text text text text text 
  text text text text text text text text text text 
  text text text text text text text text text text 
  text text text text text text text text text text 


 more text after it 

keep this argument more text after it  yet more text

 yet more text keep this argument more text after it 

 could have text here
  other other other other other other other other other other 
  other other other other other other other other other other 
  other other other other other other other other other other 
  other other other other other other other other other other 


 could have text here
  another another another another another another 
  another another another another another another 
  another another another another another another 
  another another another another another another 
 can have text here

关于正则表达式

你会注意到脚本使用了如下代码

s/\\begin{.*?}(\[.*?\])?({.*?})?//g;

这匹配

\begin{<environmentname>}
\begin{<environmentname>}[<optional arguments>]
\begin{<environmentname>}[<optional arguments>]{<mandatory arguments>}

但它这样做非贪婪方式。使它.*?不贪婪，而?分组后的()使它们可选。如果这些匹配是贪婪的（如果没有，它们将是贪婪的?），那么您将得到很多潜在的不想要的结果。

Answer