☰

使用 awk 与 while read 行进行比较

tag-icon • tag-icon text-processing sed awk search
使用 awk 与 while read 行进行比较

我有两个文件，一个有 17k 行，另一个有 4k 行。我想将第二个文件中的每一行的位置 115 与位置 125 进行比较，如果匹配，则将第一个文件中的整行写入新文件中。我想出了一个解决方案，我使用 'cat $filename | 读取文件同时阅读 LINE'。但大约需要 8 分钟才能完成。有没有其他方法像使用“awk”来减少这个过程时间。

我的代码

cat $filename | while read LINE
do
  #read 115 to 125 and then remove trailing spaces and leading zeroes
  vid=`echo "$LINE" | cut -c 115-125 | sed 's,^ *,,; s, *$,,' | sed 's/^[0]*//'`
  exist=0
  #match vid with entire line in id.txt
  exist=`grep -x "$vid" $file_dir/id.txt | wc -l`
  if [[ $exist -gt 0 ]]; then
    echo "$LINE" >> $dest_dir/id.txt
  fi
done

答案1

以下内容应该有效，已更新以去除空格：

#!/usr/bin/awk -f
# NR is the current line number (doesn't reset between files)
# FNR is the line number within the current file
# So NR == FNR  takes only the first file
NR == FNR {
    # Mark the current line as existing, via an associative array.
    found[$0]=1

    # Skip to the next line, so we don't go through the next block
    next
}
{
    # Take the columns we're looking for
    cols = substr($0,115,11)

    # Strip whitespace (space and tab) from the beginning (^) and end ($) 
    gsub(/^[ \t]+/,"", cols)
    gsub(/[ \t]+$/,"", cols)

    # Check the associative array to see if this was in the first file
    # If so, print the full line
    if(found[cols]) print;
}

将其放入文件中并使用以下命令之一进行调用

awk -f script.awk patterns.txt full.txt
./script.awk patterns.txt full.txt

相关内容