Asyptote 非官方包 arrows_pi.asy 不尊重垂直箭头的点顺序

Question

编辑于 2016 年 5 月 5 日：

抱歉，我的第一个回答。你说得对，除了垂直方向，程序尊重顺序。事实上，顺序选择仅取决于路径中点处的法线和向量的标量积(0,1)。在垂直情况下，只有一种选择。所以我修改了程序。

arrowbar EdgeArrows(arrowhead head=EdgeHead,real size=0, real angle=arrowangle,
                    filltype filltype=FillDraw, position position=EndPoint,
                    real space=infinity)
{
  return new bool(picture pic, path g, pen p, margin margin) {
    pair direction;
    real sg=sgn(dot(N,space*I*dir(g,length(g)/2)));
    space = (space == infinity) ? 2*linewidth(p) : space/2;
    if (sg>0)
      {
        direction=-space*I*dir(g,length(g)/2);
        sg=1;
      }
    else direction=space*I*dir(g,length(g)/2);
    if (sg==0)
    {
     sg=sgn(dot(N,space*dir(g,length(g)/2)));
     if (sg >0)  direction=-space*I*dir(g,length(g)/2);
     if (sg <0)  direction=space*I*dir(g,length(g)/2);
    }
    picture tpic;
    tpic.add(new void (frame f, transform t) {
        drawarrow(f,head,t*shift(inverse(t)*(-direction))*g,p,
              size,sg*angle,filltype,position,true,margin,false);
        drawarrow(f,head,t*shift(inverse(t)*direction)*reverse(g),p,
              size,sg*angle,filltype,position,true,margin,false);
      });
    tpic.addPath(g,p);
    real sz=size;
    real gle=angle;
    filltype fl=filltype;
    addArrow(tpic,head,g,p,sz,gle,fl,position(position,size,g,false));
    add(pic,tpic);
    return false;
  };
};

我做了一些测试，看起来还不错。我希望它不会引入新的错误和奇怪的行为。

奥格

第一个答案：

该例程的目标是在路径的两端放置特殊点EdgeArrow（并绘制双线）。我认为该行为是预期的，并且放置不取决于点的顺序。也许可以编写这样的函数（仅适用于直线）。作为一种解决方法，我建议RevEdgeArrows在文件中添加一些例程。

arrowhead RevEdgeHead()
{           
  arrowhead oa;
  oa.head=new path(path g, position position, pen p=currentpen, real size=0,
                   real angle=arrowangle)
    {
      if(size == 0) size=arrowsize(p);
      bool relative=position.relative;
      real position=position.position.x;
      if(relative) position=reltime(g,position);
      path r=subpath(g,position,0.0);
      pair x=point(r,0);
      real t=arctime(r,size);
      pair y=point(r,t);
      path base=y+2*size*I*dir(r,t)--y-2*size*I*dir(r,t);
      path left=rotate(-angle,x)*r;
      real[] T=arrowbasepoints(base,left,r);
      pair denom=point(right,T[1])-y;
      real factor=denom != 0 ? length((point(left,T[0])-y)/denom) : 1;
      path left=rotate(angle,x)*r;
      real[] T=arrowbasepoints(base,left,r);
      return subpath(left,0,T[0])--y--cycle;
    };
  return oa;
}

arrowhead RevEdgeHead=RevEdgeHead();


arrowbar RevEdgeArrows(arrowhead head=RevEdgeHead,real size=0, real angle=arrowangle,
                    filltype filltype=FillDraw, position position=EndPoint,
                    real space=infinity)
{
  return new bool(picture pic, path g, pen p, margin margin) {
    pair direction;
    real sg=sgn(dot(N,space*I*dir(g,length(g)/2)));
    space = (space == infinity) ? 2*linewidth(p) : space/2;
    if (sg>=0)
      {
        direction=-space*I*dir(g,length(g)/2);
        sg=1;
      }
    else direction=space*I*dir(g,length(g)/2);
    picture tpic;
    tpic.add(new void (frame f, transform t) {
        drawarrow(f,head,t*shift(inverse(t)*(direction))*g,p,
              size,sg*angle,filltype,position,true,margin,false);
        drawarrow(f,head,t*shift(inverse(t)*-direction)*reverse(g),p,
              size,sg*angle,filltype,position,true,margin,false);
      });
    tpic.addPath(g,p);
    real sz=size;
    real gle=angle;
    filltype fl=filltype;
    addArrow(tpic,head,g,p,sz,gle,fl,position(position,size,g,false));
    add(pic,tpic);
    return false;
  };
};

arrowbar RevEdgeArrows=RevEdgeArrows();

然后

import arrows_pi;
size(10cm,10cm);
draw((0.5,0)--(.5,1), EdgeArrows(), p=red);
draw((1,1)--(1,0), RevEdgeArrows(), p=red);
draw((0,0)--(1,0),EdgeArrows(), p=blue);
draw((0,-1)--(1,-1),RevEdgeArrows(), p=blue);

给出

奥格

Answer 1