差异

Question 1

你可以巧妙地做到这一点元帖子也。

\documentclass[border=5mm]{standalone}
\usepackage{luamplib}
\begin{document}
\mplibtextextlabel{enable}
\begin{mplibcode}
beginfig(1);
% unit length
u = 1cm;

% axes
path xx, yy;
xx = (1/2 left -- 5 right) scaled u;
yy = xx rotated 90;

% the pseudo-random function (with a flat spot)
path tt;
tt = ( (0,0) { dir 10 } .. 
       (1,1) { dir 70 } ..
       (2,2) { dir -30 } ..
       (4,4) { dir 0 } ) scaled u;

% find two "times" along on the path
numeric p, q;
p = directiontime right of tt;   % first time tt is horizontal 
q = 2.8;                         % a bit before point 3...

% and define the corresponding pairs
z1 = point p of tt;  
z2 = point q of tt;

% define the areas to fill
path A[];
A1 = (0,y1) -- subpath (p,q) of tt -- (0,y2) -- cycle;
A2 = (x1,0) -- (x2,0) -- subpath (q,p) of tt -- cycle;

% fill, draw and label
fill A1 withcolor .8[blue,white]; 
fill A2 withcolor .8[red,white];  

draw tt;     
drawarrow xx withcolor .5 white; 
drawarrow yy withcolor .5 white; 

label.rt ("$x$", point 1 of xx);
label.top("$y$", point 1 of yy);

dotlabel.top("$t=t_1$", z1);
dotlabel.lrt("$t=t_2$", z2);

label("$A_1$", 1/2[z1,(0,y2)]) withcolor .3 white;
label("$A_2$", 1/2[z1,(x2,0)]) withcolor .3 white;

endfig;
\end{mplibcode}
\end{document}

在这个例子中，我将其包装在luamplib，因此您需要使用进行编译lualatex。请点击链接获取更多信息。

pdflatex这是适合与和一起使用的相同图形gmp包装。

\documentclass[border=5mm]{standalone}
\usepackage{gmp}
\begin{document}
\begin{mpost}
% unit length
u = 1cm;

% axes
path xx, yy;
xx = (1/2 left -- 5 right) scaled u;
yy = xx rotated 90;

% the pseudo-random function (with a flat spot)
path tt;
tt = ( (0,0) { dir 10 } .. 
       (1,1) { dir 70 } ..
       (2,2) { dir -30 } ..
       (4,4) { dir 0 } ) scaled u;

% find two "times" along on the path
numeric p, q;
p = directiontime right of tt;   % first time tt is horizontal 
q = 2.8;                         % a bit before point 3...

% and define the corresponding pairs
z1 = point p of tt;  
z2 = point q of tt;

% define the areas to fill
path A[];
A1 = (0,y1) -- subpath (p,q) of tt -- (0,y2) -- cycle;
A2 = (x1,0) -- (x2,0) -- subpath (q,p) of tt -- cycle;

% fill, draw and label
fill A1 withcolor .8[blue,white]; 
fill A2 withcolor .8[red,white];  

draw tt;     
drawarrow xx withcolor .5 white; 
drawarrow yy withcolor .5 white; 

label.rt (\btex $x$ etex, point 1 of xx);
label.top(\btex $y$ etex, point 1 of yy);

dotlabel.top(\btex $t=t_1$ etex, z1);
dotlabel.lrt(\btex $t=t_2$ etex, z2);

label(\btex $A_1$ etex, 1/2[z1,(0,y2)]) withcolor .3 white;
label(\btex $A_2$ etex, 1/2[z1,(x2,0)]) withcolor .3 white;

\end{mpost}
\end{document}

输出应该相同，但请阅读gmp运行时选项的文档以及如何pdflatex在后台自动运行 Metapost。

差异

在序言中：

< \usepackage{luamplib}
< \mplibtextextlabel{enable}
---
> \usepackage{gmp}

要开始绘制图形：

< \begin{mplibcode}
< beginfig(1);
---
> \begin{mpost}

要创建 TeX 格式的字符串图片：

< label.rt ("$x$", point 1 of xx);
< label.top("$y$", point 1 of yy);
---
> label.rt (\btex $x$ etex, point 1 of xx);
> label.top(\btex $y$ etex, point 1 of yy);

结束一个图：

< endfig;
< \end{mplibcode}
---
> \end{mpost}

但是，如果您觉得需要为和都提供一个来源，那么您可以尝试调整这两个软件包的选项，以消除大部分（如果不是全部）差异pdflatex。lualatex有关详细信息，请参阅文档。

Answer