用中间值显示图形中的不连续性

Question 1

这是使用的一种可能方法Asymptote。虽然对于像这样的简单图表来说，这种方法可能看起来有点过于复杂，但当需要一堆类似的图表时，这种方法可能会有所帮助。它提供了两种模式，辅助草稿模式和最终模式。在辅助草稿模式中，我们定义、定位并在必要时更正图表的所有锚点。

然后我们可以定义要显示的标签以及标签所在的方向（相对于点坐标）。在最终的图表中，我们关闭所有不需要显示的绘图元素（点、标签）。

代码（文件diag.asy）：

// diag.asy
//
//   Run 
// asy diag 
//   to get asy.pdf.
//
bool draft=true;    // show temporary points
//bool draft=false;  // hide temporary points

bool showDots=true;

settings.tex="pdflatex";
import graph;
real w=6cm,h=0.618w;
size(w,h);
//size(h,w,IgnoreAspect);
import fontsize;defaultpen(fontsize(7pt));
texpreamble("\usepackage{lmodern}");

pen linePen=darkblue+0.9bp;
pen grayPen=gray(0.3)+0.8bp;
pen axisPen=grayPen;
pen line2Pen=orange+0.9bp;
pen dashPen=grayPen+linetype(new real[]{4,3})+extendcap;

arrowbar arr=Arrow(HookHead,size=3);
real arrowW=0.9bp;
pen arrowPen0=red+arrowW;
pen arrowPen1=blue+arrowW;

//
real xmin=0,xmax=1;
real ymin=0,ymax=1;

xaxis(xmin,xmax,axisPen);
yaxis(ymin,ymax,axisPen);

typedef pair pairFuncReal(real);

pairFuncReal CubicBezier(pair A, pair B, pair C, pair D){
    return new pair(real t){return A*(1-t)^3+3*B*(1-t)^2*t+3*C*(1-t)*t^2+D*t^3;};
}

pair[] p;
p.append(new pair[]{(0,0),(0,1),(0.25,0),(0,0.47),(-0.2,0.07),(0.25,0.26),(0.25,0.67),(0.62,0.89)});

p.push(0.6p[4]+0.4p[5]-(0,0.05));  // control points for f0
p.push(0.4p[4]+0.6p[5]-(0,0.05));  // 

p.push(0.6p[6]+0.4p[7]+(0,0.05));  // control points for f1
p.push(0.4p[6]+0.6p[7]+(0,0.05));  // 

pairFuncReal f0=CubicBezier(p[4],p[8],p[9],p[5]);
pairFuncReal f1=CubicBezier(p[6],p[10],p[11],p[7]);

real f0xmin=0, f0xmax=1;
real f1xmin=0, f1xmax=1;

guide g0=graph(f0,f0xmin,f0xmax);
guide g1=graph(f1,f1xmin,f1xmax);

pair arrowTail0=relpoint(g0,0.3)+(0,0.05);
pair arrowHead0=relpoint(g0,0.8)+(0,0.06);

pair arrowTail1=relpoint(g1,0.6)+(0,0.08);
pair arrowHead1=relpoint(g1,0.01)+(0,0.06);

p.append(new pair[]{
    arrowTail0,arrowHead0,arrowTail1,arrowHead1
});

draw(g0,linePen);
draw(g1,linePen);
draw(p[2]--p[6],dashPen);
draw(p[3]--(p[2].x,p[3].y),dashPen);

real r=0.04;
filldraw(circle(p[5],r),white,linePen);
fill(circle(p[6],r),linePen);

draw(p[12]--p[13],arrowPen0,arr);
draw(p[14]--p[15],arrowPen1,arr);


string[] plabels;

plabels[0]="0";
plabels[1]="1";
plabels[2]="X^\pm(\omega)";
plabels[3]="\omega";

pair[] ppos={
    plain.W,
    plain.W,
    plain.S,
    plain.W,
    plain.S,

    plain.E, // 5
    plain.SE, 
    plain.SE,
    plain.E,
    plain.E,

    plain.SE, // 10
    plain.SE,
    plain.N,
    plain.N,
    plain.N,

    plain.NW, // 15
    plain.SE,
    plain.NE,
    plain.NW,
    plain.S,
};

bool[] showDot=array(p.length,true);
//bool[] showDot=array(p.length,false);
showDot[5]=false;
showDot[6]=false;

if(showDots){
    for(int i=0;i<p.length;++i){
        if(showDot[i]) dot(p[i],UnFill);
    }
}

if(draft){
    for(int i;i<p.length;++i){
        if(p.initialized(i) && showDot[i]){
            label("$p_{"+string(i)+"}$",p[i],ppos[i]);
        }
    }
}

if(!draft){
    for(int i;i<plabels.length;++i){
        if(plabels.initialized(i) && showDot[i])
        label("$"+plabels[i]+"$",p[i],ppos[i]);
    }
}

shipout(bbox(Fill(paleyellow)));

跑去asy diag拿asy.pdf。

显示的代码是草稿模式的工作示例；要获得最终的图表，请将更改 bool draft=true;为bool draft=false; 并将 bool showDots=true;
更改为 bool showDots=false; 。

评论 1. 功能。

graph这两条曲线段是用二维绘图的标准函数构造的：

guide g0=graph(f0,f0xmin,f0xmax);
guide g1=graph(f1,f1xmin,f1xmax);

函数f0，f1接受一个实数参数t并返回计算点(x(t),y(t))。在此示例图中，两个函数被定义为三次贝塞尔线段，以方便成形：

pairFuncReal f0=CubicBezier(p[4],p[8],p[9],p[5]);
pairFuncReal f1=CubicBezier(p[6],p[10],p[11],p[7]);

这里有一个函数

pairFuncReal CubicBezier(pair A, pair B, pair C, pair D){
    return new pair(real t){return A*(1-t)^3+3*B*(1-t)^2*t+3*C*(1-t)*t^2+D*t^3;};
}

给定贝塞尔线段的控制点A,B,C,D，返回一个对象函数，该函数接受一个实参数（t，t=0..1）并返回贝塞尔线段上的对应点（A,B,C,D）。

当曲线段应该表示已知的数学函数时，f(x) 它们的定义和xmin/xmax范围需要适当改变，例如

real f0xmin=-0.2, f0xmax=0.3;
pair f0(real t){return (t,exp(t));}

评论 2. 要点和标签位置。

辅助点存储在数组中p，最初为空。

pair[] p;

我们可以将一些辅助点添加为一组：

p.append(new pair[]{(0,0),(0,1),(0.25,0),(0,0.47),(-0.2,0.07),(0.25,0.26),(0.25,0.67),(0.62,0.89)});

或者在需要时单独执行：

p.push(0.6p[4]+0.4p[5]-(0,0.05));  // control points for f0

点标签相对于点坐标的方向存储在数组中ppos：

pair[] ppos={
    plain.W,
    plain.W,
    plain.S,
    ...
};

asy基本方向在标准模块中定义plain。在草稿模式下，可以方便地填充ppos比预期锚点数量更多的元素，因为我们可以在需要时继续添加点，并在稍后更正标签的位置。

Answer