☰

如何在 LaTeX 中绘制三角形？

tag-icon • tag-icon diagrams
如何在 LaTeX 中绘制三角形？

在此处输入图片描述

我需要在 LaTeX 中绘制这个三角形和标签。我尝试查看一些代码，但我还是个业余爱好者，我不知道如何将它们重新调整到适合我的情况。

答案1

在此处输入图片描述

在 TeXLive 等现代 LaTeX 发行版中，有很多方法可以绘制此类图片。这个使用渐近线：

// tri.asy
//
// run 
// asy tri.asy
// to get tri.pdf vector image
//

settings.tex="pdflatex";
import graph;
import markers;
size(9cm);
import fontsize;defaultpen(fontsize(9pt));
texpreamble("\usepackage{lmodern}"
+"\usepackage{amsmath}"
+"\usepackage{amsfonts}"
+"\usepackage{amssymb}"
);

pen linePen=darkblue+ 0.7bp;
pen dashPen=gray(0.3)+0.7bp+linetype(new real[]{5,5})+linecap(0);

real a=60, b=40;
real alpha=30, beta=18;
pair A=(0,b), B=(a,0), C=(0,0), D;

D=extension(
  A,A+rotate(alpha)*(C-A),
  B,B+rotate(-beta)*(C-B)
);

draw(A--B--C--cycle,linePen);

draw(A--D,dashPen);
draw(B--D,dashPen);
draw(C--D,dashPen);

dot(A--B--C--D,UnFill);

markangle(Label("$\alpha$",Relative(0.5)),n=1,radius=-15,D,A,C,p=linePen+0.6bp);
markangle(Label("$\beta$", Relative(0.5)),n=1,radius=-30,C,B,D,p=linePen+0.6bp);
markangle(Label("$\phi$",  Relative(0.5)),n=1,radius=-10,D,C,B,p=linePen+0.6bp);

label("$A(0,b)$",A,plain.NW);
label("$B(a,0)$",B,plain.SE);
label("$C(0,0)$",C,plain.SW);
label("$D(x,y)$",D,plain.NE);

此代码使用给定的值a,b,alpha,beta 和函数extension(...)来查找坐标D(x,y)。

相关内容