☰

如何绘制带有角度标记的四面体？

tag-icon • tag-icon diagrams
如何绘制带有角度标记的四面体？

如何绘制具有此视角并标记特定角度的四面体？

在此处输入图片描述

谢谢

我刚刚找到一个示例代码，但我不知道如何编辑它。

\psset{viewpoint=40 10 10 rtp2xyz,lightsrc=viewpoint,Decran=30}
\begin{pspicture}[solidmemory](-2,-2)(3,3)
\psSolid[object=tetrahedron,r=3,action=draw*,name=T,num=1 2 3]% without 0
\psSolid[object=point,definition=solidgetsommet,args=T 0,text=Top,pos=uc]% Point T0 (top)
\end{pspicture}

答案1

这是你的绘画版本元帖子，您可能想了解一下。

在此处输入图片描述

这是一个lualatex可以将其创建为独立图形的程序。

\documentclass[border=5mm]{standalone}
\usepackage{luatex85}
\usepackage{luamplib}
\begin{document}
\mplibtextextlabel{enable}
\begin{mplibcode}
beginfig(1);
    z0 = origin;
    z1 = 200 right rotated -20;
    z2 = 240 right rotated 10;
    z3 = 210 right rotated 60;

    path a[];
    a1 = .85[z1,z3] {dir  20} .. .83[z2,z3];
    a2 = .90[z2,z3] {dir 210} .. .90[z0,z3];
    a3 = .86[z0,z3] {dir -30} .. .88[z1,z3];

    draw a1 withcolor 3/4 blue;
    fill a2 -- z3 -- cycle withcolor .9[blue, white];
    draw a2 withcolor .7[blue, white];
    draw a3 withcolor 3/4 blue;

    draw z0--z2 dashed withdots scaled 1/2;
    draw z0--z1--z2--z3--cycle;
    draw z1--z3;

    drawoptions(withcolor 3/4 blue);
    label.lrt(textext("$\alpha$") rotated 40, point 1/2 of a1);
    label.lft("$\beta$", z3 shifted 20 left); 
    interim ahangle := 20;
    drawarrow z3 shifted 20 left {right}..z3 shifted -(4,5);
    label.bot("$\gamma$", point 1/2 of a3);

    drawoptions();

    label.llft("$A$", z0);
    label.lrt("$B$", z1);
    label.rt("$C$", z2);
    label.top("$V$", z3);

endfig;
\end{mplibcode}
\end{document}

请注意，MP 不提供原生 3D 支持。如果你想做大量 3D 工作，那么渐近线可能是最好的 TeX 友好工具。但是有 3D 库技巧以及蒂克兹如果你有兴趣尝试的话。甚至还有 Metapost 的 3D 库（像这个) 但它们都不太容易使用。

相关内容