☰

使用 AD 将快捷方式放到用户的机器上

tag-icon • tag-icon windows-server-2003 active-directory
使用 AD 将快捷方式放到用户的机器上

我刚刚处理了一项小任务，我想通过 Active Directory 将其自动化。我们编写了一些在这里使用频繁的 Intranet 应用程序。有时，当接待员不在时，有人必须去前台处理一些事情。他们总是会打电话给我们，让我们在他们的桌面上放置一个指向这些 Intranet 应用程序的快捷方式。这有点麻烦，我相信 AD 可用于自动在用户桌面上创建指向我们 Intranet 应用程序的快捷方式。唯一的问题是，我不知道如何做到这一点，而且我们是一家小商店，目前没有系统管理员。

那么，我们如何在 Windows 2003 Server 环境中使用 AD 自动创建网站的桌面快捷方式？

答案1

使用 Windows Server 2003，您无法使用内置的组策略工具来创建和部署快捷方式。您必须使用 VBScript 来添加快捷方式。

这是我以前用过的一个

' AddDesktopShortcut - adds a desktop shortcut if one does not exist.
' 
' first argument = URL or path to desktop application
' second argument = Name of the shortcut
' third argument = path to the icon to use; this must include the icon index as well, e.g.
'                  "C:\windows\system32\shell32.dll,15". Pass an empty string, i.e. "" to
'                  use the default icon instead.

' repeat these lines for as many shortcuts as you want.
AddDesktopShortcut "http://www.google.com", "Google", ""
AddDesktopShortcut "http://www.bing.com", "Bing", "C:\Windows\System32\shell32.dll,13"

Sub AddDesktopShortcut (ByVal path, ByVal name, ByVal iconPath)
    Dim objFSO, objShell, strDesktop, objLink, strLinkPath

    Set objFSO = CreateObject("Scripting.FileSystemObject")

    Set objShell = CreateObject("WScript.Shell")
    strDesktop = objShell.SpecialFolders("Desktop")

    strLinkPath = strDesktop & "\" & name & ".lnk"
    If Not objFSO.FileExists(strLinkPath) Then
        ' shortcut doesn't exist, create it
        Set objLink = objShell.CreateShortcut(strLinkPath)
        objLink.Description = name
        If Len(iconPath) > 0 Then 
            objLink.IconLocation = iconPath 
        Else 
            ' change this line to change the default icon
            objLink.IconLocation = "C:\Windows\System32\shell32.dll,14"
        End If
        objLink.TargetPath = path
        objLink.Save
    End If

    ' clean up
    Set objLink = Nothing
    Set objShell = Nothing
    Set objFSO = Nothing
End Sub

修改脚本以添加您需要的快捷方式；上面的脚本在用户桌面添加了两个快捷方式，一个用于 Google，一个用于 Bing。

修改完脚本后，在服务器上启动组策略管理工具（开始 -> 控制面板 -> 管理工具 -> 组策略管理）。您可以使用现有的组策略，也可以为此目的创建一个新的组策略。除非您已经拥有大量组策略对象，否则创建一个新的组策略可能更容易。

在树中找到包含您想要添加快捷方式的用户/计算机的组织单位（OU）或域，右键单击并选择“在此域中创建一个新的 GPO 并将其链接到这里...”（解释 - 我面前没有 Win2003 服务器框）。

命名该 GPO，右键单击并选择编辑。然后转到树中的用户配置 -> 策略 -> Windows 设置 -> 脚本 -> 登录。右键单击它，单击属性。从那里，单击显示文件按钮，然后将脚本文件复制到那里。然后返回登录属性对话框，单击添加，然后输入/浏览到脚本文件。单击确定，关闭组策略管理编辑器窗口，您应该是正确的。

您可以使用组策略建模工具查看该 GPO 的应用位置（如果您只是按照此处的说明操作，它将应用于您选择的 OU/域中的所有用户 - 您可以使用安全组或将其链接到其他 OU 以更具体）；或者使用组策略结果工具查看它已应用的位置。

相关内容