☰

如何在多个目录中创建单个文件的多个文件？

tag-icon • tag-icon windows command-line-interface windows-command-prompt ms-dos
如何在多个目录中创建单个文件的多个文件？

您好，我想在多个目录中创建单个文件的多个副本？

例如，我有 6 个文件夹，每个文件夹中有一个名为 lp.html 的文件，我如何运行批处理来在每个目录中创建所述文件的 100 份副本。

我拥有的代码创建了多个副本，但我必须逐个执行此操作，当我有超过 100 个文件夹要执行时，这会变得非常繁琐。

那么我怎样才能让这个批处理文件完成我想要完成的任务呢？[我正在运行 Windows 7]

补充信息：所有文件夹都在同一个父文件夹中，文件夹中的文件彼此不同

   @echo off

   for /L %%i IN (1,1,100) do call :docopy %%i
   goto end

   :docopy
   set FN=00%1
   set FN=%FN:~-3%

   copy source-file.html poll%FN%.html

   :end

答案1

使用 forfiles 命令。运行 forfiles /? 获取帮助。

如果您担心并行处理副本，则可以创建 6 个不同的脚本，每个目录一个，然后从单个脚本运行它们，start scriptname.bat这样就不会等待返回值call。

答案2

试试这个。它不太美观，因为这个 *$#? 编辑器丢失了缩进、换行符等。

--- 修订脚本

@echo off

setlocal

set ROOT_DIR=c:\temp\test

for /f "tokens=*" %%D in ('dir /ad /b "%ROOT_DIR%"') do call :PROCESS_DIR "%ROOT_DIR%" "%%D"

endlocal

goto END


:PROCESS_DIR

set PD_ROOT=%1
set PD_ROOT=%PD_ROOT:"=%
set PD_DIR=%2
set PD_DIR=%PD_DIR:"=%
set PD_FIRST_FILE=
set PD_SOURCE_FILE=

REM ***
REM *** GET THE NAME OF THE FIRST FILE IN THIS FOLDER.
REM ***
for /f "tokens=*" %%F in ('dir /o-n /b "%PD_ROOT%\%PD_DIR%"') do set PD_FIRST_FILE=%%F

if "%PD_FIRST_FILE%" == "" (
    echo WARNING : No files found in [%PD_DIR%] - skipping.
    goto END
    )

set PD_SOURCE_FILE=%PD_ROOT%\%PD_DIR%\%PD_FIRST_FILE%

REM ***
REM *** CREATE FILES.
REM ***
for /l %%I in (1,1,100) do call :CREATE_FILE_COPY "%PD_ROOT%\%PD_DIR%" "%PD_SOURCE_FILE%" 00%%I

goto END

:CREATE_FILE_COPY

set CFP_DIR=%1
set CFP_DIR=%CFP_DIR:"=%
set CFP_FILE=%2
set CFP_INDEX=%3
set CFP_FILE_NO_EXT=

REM ***
REM *** GET FILE NAME WITHOUT EXTENSION.
REM ***
for /f %%F in ("%CFP_FILE%") do set CFP_FILE_NO_EXT=%%~nF

REM ***
REM *** COPY THE FILE.
REM ***
copy /y %CFP_FILE% "%CFP_DIR%\%CFP_FILE_NO_EXT%.%CFP_INDEX:~-3%

goto END


:END

相关内容