如何删除位于两个模式之间的每个记录的数据之间的换行符？

Question 1

认为这就是你想要使用 GNU sed 的结果

 sed -n '/^PATTERN_START/,/^PATTERN_END/{
         //!{H;/^Record/!{x;s/\n\([^\n]*\)$/ \1/;x}};
         /^PATTERN_START/{h};/^PATTERN_END/{x;p;x;p};d
         };p' file

解释

sed -n #Non printing


'/^PATTERN_START/,/^PATTERN_END/{
#If the line falls between these two patterns execute the next block

  //!{
  #If the previous pattern matched from the line above is not on matched(so skip 
         the start and end lines), then execute next block

        H;
        #append the line to the hold buffer, so this appends all lines between 
       #`/^PATTERN_START/` and `/^PATTERN_END/` not including those.

        /^Record/!{
        #If the line does not begin with record then execute next block

            x;s/\n\([^\n]*\)$/ \1/;x
            #Swap current line with pattern buffer holding all our other lines 
            #up to now.Then remove the last newline. As this only executed when 
            #record is not matched it just removes the newline from the start 
            #of `data`.
            #The line is then put switched back into the hold buffer.

        }
        #End of not record block

    }; 
    #End of previous pattern match block

    /^PATTERN_START/{h};

    #If line begins with `PATTERN_START` then the hold buffer is overwritten 
    #with this line removing all the previous matched lines.

    /^PATTERN_END/{x;p;x;p}
    #If line begins with `PATTERN_END` the swap in our saved lines, print them,
    #then swap back in the PATTERN END line and print that as well.

    ;d
    #Delete all the lines within the range, as we print them explicitly in the 
    #Pattern end block above


         };p' file
         # Print everything that's not in the range print, and the name of the file

Answer

认为这就是你想要使用 GNU sed 的结果

 sed -n '/^PATTERN_START/,/^PATTERN_END/{
         //!{H;/^Record/!{x;s/\n\([^\n]*\)$/ \1/;x}};
         /^PATTERN_START/{h};/^PATTERN_END/{x;p;x;p};d
         };p' file

解释

sed -n #Non printing


'/^PATTERN_START/,/^PATTERN_END/{
#If the line falls between these two patterns execute the next block

  //!{
  #If the previous pattern matched from the line above is not on matched(so skip 
         the start and end lines), then execute next block

        H;
        #append the line to the hold buffer, so this appends all lines between 
       #`/^PATTERN_START/` and `/^PATTERN_END/` not including those.

        /^Record/!{
        #If the line does not begin with record then execute next block

            x;s/\n\([^\n]*\)$/ \1/;x
            #Swap current line with pattern buffer holding all our other lines 
            #up to now.Then remove the last newline. As this only executed when 
            #record is not matched it just removes the newline from the start 
            #of `data`.
            #The line is then put switched back into the hold buffer.

        }
        #End of not record block

    }; 
    #End of previous pattern match block

    /^PATTERN_START/{h};

    #If line begins with `PATTERN_START` then the hold buffer is overwritten 
    #with this line removing all the previous matched lines.

    /^PATTERN_END/{x;p;x;p}
    #If line begins with `PATTERN_END` the swap in our saved lines, print them,
    #then swap back in the PATTERN END line and print that as well.

    ;d
    #Delete all the lines within the range, as we print them explicitly in the 
    #Pattern end block above


         };p' file
         # Print everything that's not in the range print, and the name of the file

Question 2

这是我能想到的最好的：

sed -n '/^PATTERN_START/, /^PATTERN_END/{
            /^PATTERN_START/{x;s/^.*$//;x};
            /^Record/{x;/^\n/{s/^\n//p;d};s/\n/ /gp};
            /^PATTERN_END/{x;/^\n/{s/^\n//p;d};s/\n/ /gp;g;p};
            /^Record/!H
        };   
        /^PATTERN_START/, /^PATTERN_END/!p'

解释

我假设您熟悉中的保持空间和模式空间的概念sed。在此解决方案中，我们将在模式空间中进行大量操作。因此，第一点是使用-n选项禁用自动打印并在需要的地方进行打印。

第一个任务是连接线之间的所有线Record。

考虑以下文件：

a
b
Record 1
c
d
Record 2
e
f
Record 3

连接线后，我们希望它是

a
b
Record 1 c d
Record 2 e f
Record 3

所以，这是计划：

我们读取一行，将其附加到保留空间。
如果该行以开头Record，则表示上一条记录已完成，新的记录已开始。所以我们打印出保留空间，刷新它并再次从点 1 开始。

第 1 点由代码实现/^Record/!H（命令中的第 5 行）。它的意思是“如果该行不以开头Record，则在保留空间中添加一个新行并将此行附加到保留空间”。

第 2 点可以通过代码 /^Record/{x;s/\n/ /gp;} 实现，其中x交换保持空间和模式空间，scommand 将所有\ns 替换为s，pflag 打印模式空间。使用的x还有一个优点，即现在保留空间包含当前Record行，以便我们可以开始点 1 和 2 的另一个循环。

但是，这有一个问题。在给定的示例中，第一行之前有两行 a b Record。我们不想在这些方面\n替代。由于它们不以开头Record，根据第 1 点，\n添加以保留空间，然后附加这些行。因此，如果保留空间的第一个字符是\n，则意味着Record之前没有遇到过，我们不应该\n用替换。这是通过命令完成的

/^\n/{s/^\n//p;d}

所以整个命令就变成了

/^Record/{x;/^\n/{s/^\n//p;d};s/\n/ /gp};

现在，第二个复杂的问题是，我们想要连接行，即使一行Record不是由一行Record而是由一行终止的PATTERN_END。我们想要做与第 2 点完全相同的事情，即使该行以开头PATTERN_END。所以命令变成

/^PATTERN_END/{x;/^\n/?s/^\n//p;d};s/\n/ /gp}

但是，这有一个问题。与线路的情况一样Record，PATTERN_END线路现在最终位于保留空间中。但我们知道，不会有更多的线路连接PATTERN_END。所以，我们可以打印出来。因此，我们将PATTERN_END线条带入图案空间g并使用打印它p。所以最终的命令变成

/^PATTERN_END/{x;/^\n/?s/^\n//p;d};s/\n/ /gp;g;p}

下一个问题是线条PATTERN_START。在上面的解释中，我们假设一开始，保留空间是空的。但过了一段时间后PATTERN_END，保留空间里就有东西了。（那东西只是PATTERN_END线）。当我们用开始新的循环时PATTERN_START，我们想要清除保留空间。

所以，我们要做的就是当遇到时PATTERN_START，交换保持空间和模式空间的内容，清除模式空间并再次交换。这使得保持空间干净。这正是以下命令的作用：

/^PATTERN_START/{x;s/^.*$//;x}

最后一点是，我们只想在PATTERN_START和PATTERN_END行之间进行所有这些摆弄。其他的，我们只是打印它们。这是通过命令完成的

/^PATTERN_START/, /^PATTERN_END/{
    ----above commands go here----
};
/^PATTERN_START/, /^PATTERN_END/!p

将所有这些放在一起，这给出了最终命令:)

Answer