☰

从文件资源管理器中删除 OneDrive

tag-icon • tag-icon windows-explorer onedrive windows-10
从文件资源管理器中删除 OneDrive

我想从文件资源管理器的导航面板中删除 OneDrive 选项。我发现预览时代的文章推荐注册表调整，这相当不雅观，我希望有更好的方法来删除它。

答案1

gpedit.msc -> 本地计算机策略\计算机配置\管理模板\Windows 组件\OneDrive

启用“阻止使用 OneDrive 进行文件存储”。这​​将在重启后禁用并删除所有内容

答案2

上述答案不适用于家庭用户，因为他们没有 gpedit.msc。我知道您不是在寻找注册表修复，但这似乎是唯一的方法。（您可以停止 OneDrive 启动，但不能完全删除它）

看一眼这Reddit 上的话题

编辑：
粘贴 Reddit 帖子以防万一有变化

--

如果要删除 OneDrive永久， 请执行下列操作：

打开记事本创建文本文件

继续以下链接并将代码复制/粘贴到文本文件中：

@echo off
cls

set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo Closing OneDrive process.
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo Uninstalling OneDrive.
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo Removing OneDrive leftovers.
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 

echo Removeing OneDrive from the Explorer Side Panel.
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1

pause

然后保存为 RemoveOneDrive.bat 并退出

使用管理员权限运行脚本，One Drive 将消失

相关内容