如何防止 Windows 更新在重启时安装更新？

Question

我使用 Windows 7 SP1 x64 Ultimate。我看到Control Panel\All Control Panel Items\Windows Update：

我不想安装任何 Windows 更新。如何防止 Windows 更新在重启时安装更新？

---

从那时起我就禁用了 Windows 更新：

并且cmd.exe 我已经针对最近安装的每个 Windows 更新执行了这些操作wusa /uninstall /kb:<kbnumber> 。这样够了吗？（我还没有重启电脑）

---

输出 为何重启：

输出由 Tom Mills 编写的 WMI VBScript

脚本如下（保存为.vbs文件）：

 '---------------------------------------------------------------------
'Name:   CheckPendingFileRenameOperations
'Programmer: Tom Mills/Microsoft Corp.
'Date:  8/14/2008
'Purpose: Checks registry key for pending file rename operations
'Notes:  None
'---------------------------------------------------------------------


CONST HKEY_LOCAL_MACHINE = &H80000002


strComputer = "."
strFileOps = ""


Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\"&_ 
    strComputer & "\root\default:StdRegProv")


strKeyPath = "SYSTEM\CurrentControlSet\Control\Session Manager"


strValueName = "PendingFileRenameOperations"


Return = objReg.GetMultiStringValue(HKEY_LOCAL_MACHINE,strKeyPath,_
    strValueName,arrValues)


If (Return = 0) And (Err.Number = 0) Then   
    For Each strValue In arrValues
    strFileOps = strFileOps & chr(13) & strValue
Next


    WScript.Echo "Pending File Rename Operations Found: " & strFileOps


Else
    If Err.Number = 0 Then
         Wscript.Echo "No Pending File Operations Found"
    Else
         Wscript.Echo "Check Pending File Operations failed. Error = " & Err.Number
    End If
End If