☰

Excel：表格中的出现次数

tag-icon • tag-icon microsoft-excel worksheet-function
Excel：表格中的出现次数

在 Excel 工作表中，我有一个矩形区域（C3:G7如下图所示），其中包含人员姓名（例如 Paul、John、Frank 等）。我想

  1. 创建一个唯一的（去重复的）线性名称列表（在下图中的列中 B， B9:B20但行数取决于输入范围内唯一名称的数量）。
  2. 在列 C( C9:C20) 中，计算每个名称在输入中出现的次数。（使用 可轻松完成此操作COUNTIF。）

  3. B9:C20按计数（降序）对输出列表（）进行排序。

    电子表格，第 2 行至第 7 行是输入，第 9 行至第 20 行是输出

重申一下：第 2 行到第 7 行是输入（B3:B7可以忽略），第 9 行到第 20 行是输出。我被困在第一步（生成去重的姓名列表），我也需要在第三步（对输出进行排序）上获得一些帮助。

答案1

Excel 中的 COUNTIF 函数计算符合指定条件的单元格数量

范围 - 要计数的单元格范围。在示例 C3 到 G7 中，此范围需要锁定（即行和列前面有美元符号），这样当您向下拖动单元格时，范围保持不变。

标准 - 控制应计算哪些单元格的标准。这里计算单元格 B9 中的“Chris”。

因此单元格 C9 中所需的公式是

=COUNTIF($C$3:$G$7,B9)

Excel Countif 图像

选择单元格 C9，然后将鼠标悬停在单元格 C9 的右下角，直到出现十字线，然后双击以将公式填充到单元格 C20

有关使用 countif 的更多信息可以在这里找到https://support.office.com/en-us/article/countif-function-e0de10c6-f885-4e71-abb4-1f464816df34

编辑以允许编辑问题

要对唯一名称进行排序，您将需要辅助列

在单元格 J3 中添加以下代码（注意，如大括号所示，这是作为数组公式输入的，即使用 Ctrl+Shift+Enter），然后向下拖动以填充唯一名称列表。

{=INDIRECT(TEXT(MIN(IF(($C$3:$G$7<>"")*(COUNTIF($J$2:J2,$C$3:$G$7)=0),ROW($3:$7)*100+COLUMN($C:$G),7^8)),"R0C00"),)&""}

唯一名称

与之前一样在 K3 中应用 countif，范围相同，但这次引用相邻的唯一名称单元格引用 J3，然后向下拖动。

=COUNTIF($C$3:$G$7,J3)

countif 唯一名称

现在，使用 I3 中的以下公式根据辅助计数列对唯一名称进行排序，然后向下拖动

=RANK(K3,$K$3:$K$14,0)+COUNTIF($K3:K$14,K3)-1

排名

在 A10 到 A21 中添加排名位置编号 1 到 12，然后使用 VLOOKUP 将位置编号与辅助列中的排名进行匹配，并分别返回“名称”和计数。

对于 B10 输入

=VLOOKUP($A10,$I$3:$K$14,2,FALSE)

已排序的名称

和 C10

=VLOOKUP($A10,$I$3:$K$14,3,FALSE)

已排序

突出显示 B10 和 C10，然后向下拖动以完成。

相关内容