☰

如何让 Mikrotik hAP ac3 使用前面板 LED 显示吞吐量？

tag-icon • tag-icon mikrotik-routeros
如何让 Mikrotik hAP ac3 使用前面板 LED 显示吞吐量？

可用的选项system leds set type=似乎只包括接口速度、无线信号强度、无线状态以及与吞吐量或系统负载无关的其他内容。

如何让 Mikrotik hAP ac3 显示正在使用的带宽量？

答案1

在 CLI 中，设置 LED，以便 led1-5 仅由单个 LED 组使用：

/system leds print
/system leds set 0 leds=""
/system leds add type=off leds=led1
/system leds add type=off leds=led2
/system leds add type=off leds=led3
/system leds add type=off leds=led4
/system leds add type=off leds=led5

现在，当你检查 LED 时，它看起来应该像这样：

[admin@house] > /system leds print
Flags: * - DEFAULT
Columns: TYPE, LEDS
#   TYPE       LEDS
0 * off
1 * poe-fault  poe-led
2 * off        led1
3 * off        led2
4   off        led3
5   off        led4
6   off        led5

（它添加更多“默认”条目似乎是 routerOS 7.7 中的一个错误）

现在添加一个脚本并编辑它：

/system script add name=usage-leds
/system script edit usage-leds source

将其放入编辑器中：

/interface monitor-traffic ether1 once do={
    :local r (rx-bits-per-second / 1024);
    :if ($r > 0) do={ /system leds set [find leds=led1] type=on } \
        else={ /system leds set [find leds=led1] type=off };
    :if ($r >= 138240) do={ /system leds set [find leds=led2] type=on } \
        else={ /system leds set [find leds=led2] type=off };
    :if ($r >= 276480) do={ /system leds set [find leds=led3] type=on } \
        else={ /system leds set [find leds=led3] type=off };
    :if ($r >= 414720) do={ /system leds set [find leds=led4] type=on } \
        else={ /system leds set [find leds=led4] type=off };
    :if ($r >= 552960) do={ /system leds set [find leds=led5] type=on } \
        else={ /system leds set [find leds=led5] type=off };
}

常数以 kbps 为单位，可以设置为您想要的阈值。这些常数甚至来自“任何流量”，部分最高可达 540mbps (540*1024)，以实现完全偏转。

现在安排它运行：

system scheduler add disabled=no interval=1s name="load LEDs" on-event=usage-leds

运行速度测试或者其他测试，然后观察 LED 指示的使用情况。

相关内容