☰

弦理论的“标志”该怎么画？

tag-icon • tag-icon fun
弦理论的“标志”该怎么画？

我想知道是否可以用 LaTeX 绘制弦理论的“徽标”。我认为这是可行的，但不确定如何做。有哪位大师想试一试吗？

Calbi-Yau 流形的 3-D 投影

来源：https://commons.wikimedia.org/wiki/File:Calabi-Yau-alternate.png并且（质量更好）https://commons.wikimedia.org/wiki/File:Calabi-Yau.png（均为 Lunch 自己的作品；CC BY-SA 2.5）

答案1

我在网上搜索了一下，找到了五次 6D Calabi-Yau 截面的参数化，所以这里是渐近线执行：

\documentclass{standalone}
\usepackage{asymptote}

\begin{document}

\begin{asy}[width=10cm,height=10cm]
import graph3;

size3(200);
currentprojection=orthographic(3,3,2);
currentlight=light(8,10,2);

int k1, k2, n = 5;
real alpha = 0.3*pi;

// cross section of the quintic 6D Calabi-Yau manifold
triple cy(pair z) {  

  pair z1, z2;

  if(z==(0,0)) {
    z1 = exp(2*pi*I*k1/n);
    z2 = 0;
  } else {
    z1 = exp(2*pi*I*k1/n)*exp(log(cos(I*z))*2/n);
    z2 = exp(2*pi*I*k2/n)*exp(log(-I*sin(I*z))*2/n);
  }

  return (z2.x, cos(alpha)*z1.y + sin(alpha)*z2.y, z1.x);

}

for(k1=0; k1<n; ++k1) {
  for(k2=0; k2<n; ++k2) {
    surface s = surface(cy,(-1,0),(1,0.5*pi),20,20);
    draw(s,yellow+orange);
  }
}

\end{asy}

\end{document}

在此处输入图片描述

不知道你的“徽标”中显示的是哪一个，但那至少是一个卡拉比-丘流形。如果你用 acroread 查看生成的 PDF，你可以旋转这个怪物。

相关内容