参考书目：您不能弹出一个空的文字堆栈进行输入

Question

noon.bst使用类似的线条

"[" write$  short.list write$ " " write$ format.date "year" output.check write$ "] " write$

再次在参考书目开头打印引用标签。

有问题的是

format.date "year" output.check write$

如果有要打印的内容output.check将自行执行write$，因此我们最终可能会得到

format.date write$ write$

在许多情况下。这会导致您报告的错误。

显然，有人已经注意到了这个问题，并已经从一些FUNCTIONs 中删除了有问题的部分，因此在某些情况下，我们发现

"[" write$  short.list write$ " " year * write$ "] " write$

但他们错过或忽略了一些事件。

我建议采用一种略有不同的方法，我们将标签生成外部化为FUNCTION模仿实际引用标签生成的方式。

noon.bst您可以获取修复版本https://gist.github.com/moewew/a4d48dd54655a610ae9b68522a5f48aa. 与原版的差异noon.bst来自https://textuploader.com/1qfzj是

--- orig-noon.bst   2020-04-29 08:44:11.162162900 +0200
+++ noon.bst    2020-04-28 22:18:25.871804100 +0200
@@ -982,9 +982,26 @@
 { organization "organization" bibinfo.check format.org.or.pub
 }

+FUNCTION {bib.label}
+{
+  "["
+  short.list
+  *
+  " "
+  *
+  year duplicate$ empty$
+  short.list key field.or.null = or
+     { pop$ "" }
+     'skip$
+  if$
+  *
+  "] \newblock"
+  *
+}
+
 FUNCTION {article}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   format.authors "author" output.check
   author format.key output
   new.block
@@ -1008,7 +1025,7 @@
 }
 FUNCTION {book}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   author empty$
     { format.editors "author and editor" output.check
       editor format.key output
@@ -1042,7 +1059,7 @@
 }
 FUNCTION {booklet}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   format.authors output
   author format.key output
   new.block
@@ -1058,7 +1075,7 @@

 FUNCTION {inbook}
 { output.bibitem
-  "[" write$  short.list write$ " " write$ format.date "year" output.check write$ "] " write$
+  bib.label write$ newline$
   author empty$
     { format.editors "author and editor" output.check
       editor format.key output
@@ -1098,7 +1115,7 @@

 FUNCTION {incollection}
 { output.bibitem
-  "[" write$  short.list write$ " " write$ format.date "year" output.check write$ "] " write$
+  bib.label write$ newline$
   format.authors "author" output.check
   author format.key output
   new.block
@@ -1125,41 +1142,41 @@
 }
 FUNCTION {inproceedings}
 { output.bibitem
-  "[" write$  short.list write$ " " write$ format.date "year" output.check write$ "] " write$
-  format.authors "author" output.check
-  author format.key output
-  new.block
-  format.title "title" output.check
-  new.block
-  crossref missing$
-    { format.in.ed.booktitlenoit "booktitle" output.check
-      format.bvolumenoit output
-      format.number.series output
-      format.pages output
-      new.sentence
-      publisher empty$
-        { format.organization.address output }
-        { organization "organization" bibinfo.check output
-          format.publisher.address output
-        }
-      if$
-      %format.date "year" output.check
-     year write$ ", " write$ 
-    }
-    { format.incoll.inproc.crossref output.nonnull
-      format.pages output
-      %format.date "year" output.check
-     year write$ ", " write$ 
-    }
+  new.block
+  bib.label write$ newline$
+  format.authors "author" output.check
+  author format.key output
+  new.block
+  format.title "title" output.check
+  new.block
+  crossref missing$
+    { format.in.ed.booktitlenoit "booktitle" output.check
+      format.bvolumenoit output
+      format.number.series output
+      format.pages output
+      new.sentence
+      publisher empty$
+        { format.organization.address output }
+        { organization "organization" bibinfo.check output
+          format.publisher.address output
+        }
+      if$
+      %format.date "year" output.check
+  year write$ ", " write$ 
+    }
+    { format.incoll.inproc.crossref output.nonnull
+      format.pages output
+      %format.date "year" output.check
+  year write$ ", " write$ 
+    }
   if$
-  new.block
   format.note output
   fin.entry
 }
 FUNCTION {conference} { inproceedings }
 FUNCTION {manual}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   format.authors output
   author format.key output
   new.block
@@ -1176,7 +1193,7 @@

 FUNCTION {mastersthesis}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   format.authors "author" output.check
   author format.key output
   new.block
@@ -1194,8 +1211,7 @@

 FUNCTION {misc}
 { output.bibitem
-%  "[" write$  short.list write$ " " year * write$ "] " write$
-  "[" write$  short.list write$  "] " write$
+  bib.label write$ newline$
 %  format.authors output
 %  author format.key output
   new.block
@@ -1209,7 +1225,7 @@
 }
 FUNCTION {phdthesis}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   format.authors "author" output.check
   author format.key output
   new.block
@@ -1227,7 +1243,7 @@

 FUNCTION {proceedings}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   format.editors output
   editor format.key output
   new.block
@@ -1249,7 +1265,7 @@

 FUNCTION {techreport}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   format.authors "author" output.check
   author format.key output
   new.block
@@ -1267,7 +1283,7 @@

 FUNCTION {unpublished}
 { output.bibitem
-  "[" write$  short.list write$ " " year * write$ "] " write$
+  bib.label write$ newline$
   format.authors "author" output.check
   author format.key output
   new.block
@@ -1384,6 +1400,7 @@
   'label :=
 }

+
 FUNCTION {sort.format.names}
 { 's :=
   #1 'nameptr :=

Answer 1