如何阻止 Asymptote 上的 3D 标签自动填充颜色？

Question

我试图在 Asymptote 中的 3D 矢量后面添加标签，这些标签用不同的颜色绘制。我希望所有标签都为黑色，但即使声明颜色后标签没有区别。输出如下所示：

我该如何解决这个问题？谢谢！

import math;
settings.outformat="pdf";
settings.prc=true;
settings.embed=true;
settings.render=0;
size(5cm,0);
import graph3;

triple F(pair uv) {
real r = uv.x;
real t = uv.y;
return (r*cos(t),r*sin(t), r);}
surface coneup = surface(F, (0,0), (1,2pi), Spline);
draw(coneup, surfacepen=material(paleyellow, emissivepen=0.2 paleyellow), light=Viewport);

triple F2(pair uv) {
real r = uv.x;
real t = uv.y;
return (r*cos(t),r*sin(t), -r);}
surface conedown = surface(F2, (0,0), (1,2pi), Spline);
draw(conedown, surfacepen=material(paleyellow, emissivepen=0.2 paleyellow), light=Viewport);

draw(O--X, Arrow3);
draw(O--Y, Arrow3);
draw(O--Z, Arrow3);

draw(O--Y+Z, L=Label("null", position=EndPoint), yellow, Arrow3);
draw(O--.5*X+1.5*Z, L=Label("timelike", position=EndPoint), green, Arrow3);
draw(O--1.5*X+0.5*Z, L=Label("spacelike", position=EndPoint), red, Arrow3);

---

编辑：我尝试将标签放在一个极小的片段中

draw(0.99*(Y+Z) -- Y+Z, L=Label("null", position=EndPoint));

但它只生产出了一个全黑的标签盒。所以问题不在于颜色。

Answer 1

感谢您报告此错误。以后，请通过以下地址报告错误https://github.com/vectorgraphics/asymptote/issues

修复现已包含在 git 中，并将包含在即将发布的 2.84 版本中。

请谨慎使用 settings.render=0；此方法仅对隐藏表面移除、照明和透明度提供有限的支持。请参阅 https://asymptote.sourceforge.io/doc/three.html

与此同时，如果你真的希望继续使用实验性的settings.render=0 选项，您可以从 three.asy 的副本中删除以下标记为 - 的行：

diff --git a/base/three.asy b/base/three.asy
index c208f59d..9dfad6ce 100644
--- a/base/three.asy
+++ b/base/three.asy
@@ -2907,11 +2907,6 @@ object embed(string prefix=outprefix(), string label=prefix,
   if((preview || (prc && settings.render == 0)) && settings.embed) {
     image=prefix;
     if(settings.inlinetex) image += "_0";
-    if(!preview && !S.pic2.empty2()) {
-      transform T=S.pic2.scaling(S.width,S.height);
-      _shipout(image,S.pic2.fit(T),newframe,nativeformat(),false,false);
-    }
-
     image += "."+nativeformat();
     if(!settings.inlinetex) file3.push(image);
     image=graphic(image,"hiresbb");

Answer 2

我会使用内置函数unitcone进行一些几何变换。关于颜色：只需使用black内部函数Label为其字符串着色即可。希望现在代码很简单。

// http://asymptote.ualberta.ca/
size(6cm,0);
import three;
currentprojection=orthographic(3,2,1,zoom=.9,center=true);

surface conedown=shift(0,0,-1)*unitcone;
surface coneup=scale(1,1,-1)*conedown;
material p=material(paleyellow,emissivepen=0.2 paleyellow);
draw(coneup,surfacepen=p,light=Viewport);
draw(conedown,surfacepen=p,light=Viewport);

draw(O--X, Arrow3);
draw(O--Y, Arrow3);
draw(O--Z, Arrow3);
draw(Label("null",EndPoint,align=E,black),O--Y+Z,yellow,Arrow3);
draw(Label("time-like",EndPoint,black),O--.5*X+1.5*Z,green,Arrow3);
draw(Label("space-like",EndPoint,black),O--1.5*X+0.5*Z,red,Arrow3);