☰

根据两列上的变量值对多个数据框的行进行子集化

tag-icon • tag-icon linux shell
根据两列上的变量值对多个数据框的行进行子集化

我有多个数据框，如下所示：

df1

col1;col2;col3;col4
cat;1;2;blue
house;1;2;red
dog;5;6;yellow
mouse;7;8;white

df2

col1;col2;col3;col4
cat;3;4;grey
house;7;8;red
dog;5;6;yellow
mouse;3;4;black

df3

col1;col2;col3;col4
cat;5;6;grey
house;3;4;red
dog;5;6;yellow
mouse;9;10;grey

我想对 col2 和 col3 的值等于“cat”的 col2 和 col3 的值的所有行进行子集 col2 和 col3 的值在每个数据帧中不断变化，因此不是恒定的。输出将是：

df1

col1;col2;col3;col4
cat;1;2;blue
house;1;2;red

df2

col1;col2;col3;col4
cat;3;4;grey
mouse;3;4;black

df3

col1;col2;col3;col4
cat;5;6;grey
dog;5;6;yellow

有什么建议吗？事实上我可以一直使用 awk：

awk -F";" '{if($2=="1" && $3=="2")print $0}' df1 
awk -F";" '{if($2=="3" && $3=="4")print $0}' df2
awk -F";" '{if($2=="5" && $3=="6")print $0}' df3

但我有数千个数据框，所以手动输入每行代码的值很麻烦

答案1

怎么样

awk -F\; '                              # set field separator
FNR == 1        {D1 = D2 = ""           # on new file (= line No. 1), reset variables
                 FN = FILENAME "_tmp"   # compose new filename
                 print > FN             # print header line to new file
                }
/^cat/          {D2 = $2                # if found "cat", set variables D2 and 
                 D3 = $3                # D3
                }
$2 == D2 &&                             # if fields $2 and $3 match variables, i.e. $2 and $3 from "cat" line
$3 == D3        {print > FN             # print line to new file
                }
' df*                                   # work on every "df*" file in sight

然后mv将 *tmp 文件覆盖原始文件...

相关内容