☰

如何在 emacs 上的功能之间快速导航/跳转？

tag-icon • tag-icon c linux windows emacs
如何在 emacs 上的功能之间快速导航/跳转？

如何在 emacs 上的函数之间快速导航/跳转？我正在寻找一种在 emacs 上快速跳转到函数的方法。我正在使用 emacs 搜索来执行此操作，但它太慢而且会失败。例如，我需要确保输入一个与函数原型或函数调用不匹配的字符串。我需要在其中包含函数类型和参数类型的请求。并且根据程序中使用的编码语法样式，这很难/不可行。我到底在寻找什么：我只需输入函数名称并跳转到它的请求。我目前使用的语言是 Linux 上的 C。但如果其他编程语言和平台有这样的功能，请也向我展示。将不胜感激。

请注意：不要建议“使用 IDE”，我对 emacs 很满意。

答案1

M-x imenu让您跳转到同一文件中的函数。我已将其绑定到 Super-i 以方便访问。

答案2

我一直在使用cscope集成到 Emacs 中的功能，它在搜索函数、变量等并在它们之间跳转方面表现得非常好。

编辑：在 .emacs （或 .xemacs/init.el）中我有：

(require 'xcscope)
(setq cscope-do-not-update-database t)

然后我只需根据需要在源文件上手动运行 cscope（对于 Linux 内核，make cscope它也适用于许多其他大型项目）。

答案3

正如其他人所建议的，我也Imenu专门使用它在缓冲区中导航。我发现通过 Imenu 界面来实现这一点非常有用ido。这是我的配置ido-imenu。（这是从 emacswiki 页面中找到的功能略微修改的版本）

(defun ido-imenu ()
  "Update the imenu index and then use ido to select a symbol to navigate to.
Symbols matching the text at point are put first in the completion list."
  (interactive)
  (imenu--make-index-alist)
  (let ((name-and-pos '())
        (symbol-names '()))
    (flet ((addsymbols
            (symbol-list)
            (when (listp symbol-list)
              (dolist (symbol symbol-list)
                (let ((name nil) (position nil))
                  (cond
                   ((and (listp symbol) (imenu--subalist-p symbol))
                    (addsymbols symbol))

                   ((listp symbol)
                    (setq name (car symbol))
                    (setq position (cdr symbol)))

                   ((stringp symbol)
                    (setq name symbol)
                    (setq position
                          (get-text-property 1 'org-imenu-marker symbol))))

                  (unless (or (null position) (null name))
                    (add-to-list 'symbol-names name)
                    (add-to-list 'name-and-pos (cons name position))))))))
      (addsymbols imenu--index-alist))
    ;; If there are matching symbols at point, put them at the beginning
    ;; of `symbol-names'.
    (let ((symbol-at-point (thing-at-point 'symbol)))
      (when symbol-at-point
        (let* ((regexp (concat (regexp-quote symbol-at-point) "$"))
               (matching-symbols
                (delq nil (mapcar
                           (lambda (symbol)
                             (if (string-match regexp symbol) symbol))
                           symbol-names))))
          (when matching-symbols
            (sort matching-symbols (lambda (a b) (> (length a) (length b))))
            (mapc
             (lambda (symbol)
               (setq symbol-names (cons symbol (delete symbol symbol-names))))
             matching-symbols)))))
    (let* ((selected-symbol (ido-completing-read "Symbol? " symbol-names))
           (position (cdr (assoc selected-symbol name-and-pos))))
      (push-mark)
      (if (overlayp position)
          (goto-char (overlay-start position))
        (goto-char position)))))

(global-set-key (kbd "C-x C-i") 'ido-imenu)

我可以使用C-xC-i多种支持语言的模式imenu

相关内容