如何使用渐近线从 .csv 绘制 3D 曲面图

Question

对于示例渐近线：根据 3D 中的数据点绘制曲面，数据组织得非常好。文件 data.csv 只有 3 列，分别为 x_i、y_j、z_(i,j)，首先在 i 中，然后是 j 中。

第一个任务是清理data.csv文件，即删除第一行包含字符而不是数据以及一个空白行。那是我的data1.csv。此外，不要使用in作为名称，因为它是带有 Asymptote 的关键字。由于它有三列，所以real[][] a=fic.dimension(0,3)可以完成工作。a[i]是包含的文件的第 i+1 行x,y,z。

就像渐近线：根据 3D 中的数据点绘制曲面，至少有一个解决方案来绘制表面。

解决方案 1： surface(triple[][] f, real [] x,real [] y) 我们需要构造、x和y。z给出ymesh/15了循环的方法。为了简化，我使用b=transpose(a)（它避免了一个循环）。

请查看代码（请注意，我使用缩放z以使表面不太平坦）。

import three;
import grid3;
import graph3;
import palette;


// since the value of z=f(x,y) are small
// there is scaling in z
unitsize(.5cm,.5cm,2cm);
currentprojection=orthographic(18,17,3);

bool renderPRC = true; //Pretty essential for me, I would like to obtain graph in PRC format

if(renderPRC) {
    // PRC TRUE
    settings.prc=true;
    settings.embed=true;
}
else {
    // RASTERIZE
    settings.outformat="png";
    settings.prc=false;
    settings.render=3;
}

// data1.csv is a refactorized to eliminate the first line containing string
// and also a blank line
file fic =input("data1.csv").line().csv(); 

// it is 3 columns 
real[][] a=fic.dimension(0,3);
// a[i] is 3 array of x,y,z value

int xmesh=15;
int ymesh=a.length#15;
real [][] b=transpose(a);

// solution 1 : construct the vectors real []x, real [] y and the matrix real[][] z
// which correspond to the grid and the values on the grid
real [] xpt,ypt;
ypt=b[1][0:ymesh];
for(int i=0;i<xmesh;++i)
{
    xpt.push(b[0][i*ymesh]);
}
real[][] zpt=new real[xmesh][ymesh];
for(int i=0;i<xmesh;++i)
{
    for (int j=0;j<ymesh;++j)
    {
        write(i,j);
        zpt[i][j]=b[2][i*ymesh+j];
    }
}


surface s=surface(zpt,xpt,ypt,Spline);
s.colors(palette(s.map(zpart),Rainbow()));
draw(s);
xaxis3(Label("$x$",.1),Bounds,InTicks);
yaxis3(Label("$y$",0.5),Bounds,InTicks);
zaxis3(Label("$z$",0.5),Bounds,InTicks(beginlabel=false));

结果

解决方案 2：创建一个函数

就像渐近线：根据 3D 中的数据点绘制曲面，可以使用f依赖于两个变量的函数并绘制所需的参数曲面。在我看来，这更难理解，给出正确的参数至关重要。请查看代码

//Necessary module imports
import three;
import grid3;
import graph3;
import palette;


// since the value of z=f(x,y) are small
// there is scaling in z
unitsize(.5cm,.5cm,2cm);
currentprojection=orthographic(18,17,3);

bool renderPRC = true; //Pretty essential for me, I would like to obtain graph in PRC format

if(renderPRC) {
    // PRC TRUE
    settings.prc=true;
    settings.embed=true;
}
else {
    // RASTERIZE
    settings.outformat="png";
    settings.prc=false;
    settings.render=3;
}

// data1.csv is a refactorized to eliminate the first line containing string
// and also a blank line
file fic =input("data1.csv").line().csv(); 

// it is 3 columns 
real[][] a=fic.dimension(0,3);
// a[i] is 3 array of x,y,z value

int xmesh=15;
int ymesh=a.length#15;
real [][] b=transpose(a);


// Solution 2 : create a function.
// Be careful the arguments for the surface creation are strongly related
// to the shape of the data
triple f (pair t) {
return (b[0][round(t.x)*ymesh],b[1][round(t.y)],b[2][round(t.x)*ymesh+round(t.y)]);
}

surface ns=surface(f,(0,0),(xmesh-1,ymesh-1),xmesh-1,ymesh-1,Spline);
ns.colors(palette(ns.map(zpart),Rainbow()));
draw(ns);


xaxis3(Label("$x$",.1),Bounds,InTicks);
yaxis3(Label("$y$",0.5),Bounds,InTicks);
zaxis3(Label("$z$",0.5),Bounds,InTicks(beginlabel=false));

结果相同

Answer 1